home *** CD-ROM | disk | FTP | other *** search
/ Night Owl 6 / Night Owl's Shareware - PDSI-006 - Night Owl Corp (1990).iso / 001a / mskrmsrc.zip / MSSKER.ASM < prev    next >
Assembly Source File  |  1991-10-24  |  75KB  |  2,359 lines
  1.     NAME    mssker
  2. ; File MSSKER.ASM
  3.     include mssdef.h
  4. ; Edit history:
  5. ; 6 Sept 1991 version 3.11
  6. ; Last edit 6 Sept 1991
  7. ;****************************** Version 3.10 ***************************** 
  8. ; KERMIT, Celtic for "free" 
  9. ;
  10. ; The name "Kermit" is a registered trade mark of Henson Associates, Inc.,
  11. ; used by permission.
  12. ;
  13. ;    MS-DOS Kermit Program Version 3.11, 6 Sept 1991
  14. ;    MS-DOS Kermit Program Version 3.10, 2 March 1991
  15. ;    MS-DOS Kermit Program Version 3.02, development for 3.10, 1990-91
  16. ;    MS-DOS Kermit Program Version 3.01, 20 March 1990
  17. ;    MS-DOS Kermit Program Version 3.00, 16 Jan 1990 
  18. ;    Kermit-MS Program Version 2.32, 11 Dec 1988 
  19. ;    Kermit-MS Program Version 2.31, 1 July 1988
  20. ;       Kermit-MS Program Version 2.30, 1 Jan 1988
  21. ;    Kermit-MS Program Version 2.29, 26 May 1986, plus later revisions.
  22. ;       Kermit-MS Program Version 2.27, December 6,1984
  23. ;       Kermit-MS Program Version 2.26, July 27, 1984
  24. ;       PC-Kermit Program Version 1.20, November 4, 1983
  25. ;       PC-Kermit Program Version 1.0, 1982
  26. ; 
  27. ;       Based on the Columbia University KERMIT Protocol.
  28. ; 
  29. ;       Copyright (C) 1982,1991, Trustees of Columbia University in the
  30. ;       City of New York.  Permission is granted to any individual or
  31. ;       institution to use, copy, or redistribute this software as long as
  32. ;       it is not sold for profit and this copyright notice is retained.
  33. ;
  34. ;       Original Authors (versions 1.0 through 2.28):
  35. ;         Daphne Tzoar, Jeff Damens
  36. ;         Columbia University Center for Computing Activities
  37. ;         612 West 115th Street
  38. ;         New York, NY  10025
  39. ;
  40. ;       Present author (version 2.29, 2.30, 2.31, 2.32, 3.00, 3.01, 3.02,
  41. ;            3.10, 3.11):
  42. ;         Joe R. Doupnik
  43. ;      Dept of EE, and CASS
  44. ;      Utah State University
  45. ;      Logan, UT  84322, USA
  46. ;      E-Mail: JRD@CC.USU.EDU (Internet), JRD@USU (BITNET)
  47. ; 
  48. ; Special thanks to Christine Gianone, Frank da Cruz, Bill Catchings, 
  49. ; Bernie Eiben, Vace Kundakci, Terry Kennedy, Jack Bryans, and many many
  50. ; others for their help and contributions.
  51.  
  52.     public    dosnum, curdsk, fpush, isfile, sbrk, crun, errlev
  53.     public    takrd, takadr, taklev, filtst, maxtry, dskspace, thsep, tdfmt
  54.     public    lclsusp, lclrest, lclexit, cwdir, kstatus, verident, cdsr
  55.     public    spath, patched, oldtak, getenv, psp, dosctty, patchid
  56.  
  57.     public    tcptos
  58.  
  59. env    equ    2CH            ; environment address in psp
  60. cline    equ    80H            ; offset in psp of command line
  61. braceop    equ    7bh            ; opening curly brace
  62. bracecl    equ    7dh            ; closing curly brace
  63.  
  64. _STACK    SEGMENT                ; our stack
  65.     dw    1500 dup (0)        ; for TCP code
  66.     dw    200 dup(0)        ; for main Kermit code
  67. msfinal    label    word            ; top of stack
  68. _STACK    ENDS
  69.  
  70. data   segment
  71.     extrn    buff:byte, comand:byte, flags:byte, trans:byte,    prmptr:word
  72.     extrn    machnam:byte, decbuf:byte, rstate:byte, sstate:byte
  73.     extrn    mcctab:byte
  74.  
  75. verident label    byte
  76.     verdef
  77.     db    ' patch level'
  78. patchid    db    ' 0 $'
  79. copyright db    cr,lf
  80.     db    'Copyright (C) Trustees of Columbia University 1982, 1991.'
  81.     db    cr,lf,'$'
  82. hlpmsg    db     cr,lf,'Type ? or HELP for help',cr,lf,'$'
  83. crlf    db      cr,lf,'$'
  84. ermes1    db    cr,lf,'?More parameters are needed$'
  85. ermes2    db    cr,lf,'?Unable to initialize memory$'
  86. ermes3  db      cr,lf,'?Command canceled$'
  87. ermes4    db    '?Unable to change directory',0            ; asciiz
  88. ermes5    db    cr,lf,'?Unable to complete initialization process$'
  89. ermes6    db    cr,lf,'Ignoring patch file MSKERMIT.PCH. '
  90.     db    'Version number mismatch.',cr,lf,'$'
  91. ermes7    db    cr,lf,'Patch file MSKERMIT.PCH was not found',cr,lf,'$'
  92. ermes8    db    cr,lf,'Fatal error in MSKERMIT.PCH! Please remove PATCH '
  93.     db    'command.',cr,lf,'$'
  94. erms30    db    cr,lf,'?Passed maximum nesting level for TAKE command$'
  95. erms31    db    cr,lf,'?Cannot find Take-file: $'
  96. erms34    db    cr,lf,'This program requires DOS 2.0 or above$'
  97. erms37    db    cr,lf,'?Unable to execute program$'
  98. badnam    db    cr,lf,'?No such file(s)$'
  99. filmsg    db    ' Filename$'
  100. dskmsg    db    ' disk drive letter or Return$'
  101. pthmsg    db    ' Name of new working directory and/or disk$'
  102. runmsg    db    ' program name and command line$'
  103. tophlp    db    cr,lf
  104.     db    '  Ask, Askq (read keybd to variable) '
  105.     db    '  Open Read/Write/Append file  scripts'
  106.     db    cr,lf
  107.     db    '  Bye      (logout remote server)    '
  108.     db    '  Output text     (for scripts)'
  109.     db    cr,lf
  110.     db      '  C or Connect  (become a terminal)  '
  111.     db    '  Pause [seconds] (for scripts)'
  112.     db    cr,lf
  113.     db    '  Clear    (clear serial port buffer)'
  114.     db    '  Pop, End (exit current macro/Take file)'
  115.     db    cr,lf
  116.     db    '  Close    (logging and script file) '
  117.     db    '  Push     (go to DOS, keep Kermit)'
  118.     db    cr,lf
  119.     db    '  CLS (clear screen at command level)'
  120.         db      '  Quit     (leave Kermit)'
  121.     db    cr,lf
  122.     db    '  CWD or CD  (change dir &/or disk)  '
  123.         db      '  R or Receive  (opt local filename)'
  124.     db    cr,lf
  125.     db    '  Define/Assign   (a command macro)  '
  126.     db    '  Read (line from a file to variable)'
  127.     db    cr,lf
  128.     db    '  Delete   (a file)                  '
  129.     db    '  Reinput  (script Input, reread buffer)'
  130.     db    cr,lf
  131.     db    '  Directory                          '
  132.     db    '  Remote   (prefix for commands)'
  133.     db    cr,lf
  134.     db    '  Disable  (selected server commands)'
  135.     db    '  Replay   (file through term emulator)'
  136.     db    cr,lf
  137.     db    '  Do       (a macro)                 '
  138.     db    '  Run      (a program)'
  139.     db    cr,lf
  140.     db    '  Echo text (show line on screen)    '
  141.         db      '  S or Send  local file   new name'
  142.     db    cr,lf         
  143.     db    '  Enable   (selected server commands)'
  144.     db    '  Server [timeout] (become a server)'
  145.     db    cr,lf
  146.     db      '  EXIT     (leave Kermit)            '
  147.         db      '  Set      (most things)'
  148.     db    cr,lf
  149.     db    '  Finish   (to remote server)        '
  150.     db    '  Show     (most things)'
  151.     db    cr,lf
  152.     db    '  Get      (remote file opt new name)'
  153.     db    '  Space    (free on current disk)'
  154.     db    cr,lf
  155.     db    '  Goto    (label, Take file or Macro)'
  156.         db      '  Status   (show main conditions)'
  157.     db    cr,lf
  158.     db    '  Hangup   (drop DTR, hang up phone) '
  159.     db    '  Stop     (exit all Take files & macros)'
  160.     db    cr,lf
  161.     db    '  If [not] <condition> <command>     '
  162.     db    '  Take     (do a command file)'
  163.     db    cr,lf
  164.     db    '  I or Input [timeout] text (scripts)'
  165.     db    '  Transmit filespec [prompt] (raw upload)'
  166.     db    cr,lf
  167.     db    '  Log (Packet, Session, Transaction) '
  168.     db    '  Type     (a file)'
  169.     db    cr,lf
  170.     db    '  Logout   (remote server)           '
  171.     db    '  Wait [timeout] on modem \cd \cts \dsr'
  172.     db    cr,lf
  173.     db    '  Mail     (file to host Mailer)     '
  174.     db    '  Write  FILE or log file   text'
  175.     db    '$'
  176.  
  177. data    ends
  178.  
  179. data1    segment
  180. qckhlp    db cr,lf
  181.     db '                    Introduction to MS-DOS Kermit',cr,lf
  182.     db 'o An MS-Kermit command is a line of words separated by spaces and'
  183.     db ' ending with',cr,lf,'  a carriage return <the Enter key>.'
  184.     db '  Example: SET SPEED 2400<Enter>',cr,lf
  185.     db 'o Most words can be abbreviated and can be completed by pressing'
  186.     db ' the Esc key.',cr,lf
  187.     db '  Example: SET SPE 24<Enter>  or even  SET SPE<Esc> 24<Esc>'
  188.     db '<Enter>',cr,lf
  189.     db 'o Help (detailed, specific): press the "?" key where a word would'
  190.     db ' appear.',cr,lf
  191.     db 'o Edit lines using the Backspace key to delete characters,'
  192.     db ' Control-W to delete',cr,lf
  193.     db '  words, and Control-U to delete the line.  Control-C cancels the'
  194.     db ' command.',cr,lf
  195.     db 'o Frequently used MS-Kermit commands:',cr,lf
  196.     db '  EXIT           Leave the Kermit program. QUIT does the same'
  197.     db ' thing.',cr,lf
  198.     db '  SET            PORT, PARITY, SPEED, TERMINAL and many other'
  199.     db ' parameters.',cr,lf
  200.     db '  SHOW or STATUS Display groups of important parameters.'
  201.     db ' SHOW ? for categories.',cr,lf,lf
  202.     db '  CONNECT        Establish a terminal connection to a remote'
  203.     db ' system or a modem.',cr,lf
  204.     db '  Control-$'
  205. qckhlp1    db ' C    (Control-$'
  206. qckhlp2    db '  followed by "C")  Return to MS-Kermit> prompt.',cr,lf,lf
  207.     db '  SEND filename  Send the file(s) to Kermit on the other'
  208.     db ' computer.',cr,lf
  209.     db '  RECEIVE        Receive file(s), SEND them from Kermit on the'
  210.     db ' other computer.',cr,lf
  211.     db '  GET filename   Ask the remote Kermit server to send the file(s)'
  212.     db ' to us.',cr,lf
  213.     db '  FINISH         Shut down remote Kermit but stay logged into'
  214.     db ' remote system.',cr,lf
  215.     db '  BYE            FINISH and logout of remote system and exit'
  216.     db ' local Kermit.',cr,lf
  217.     db 'o Common startup sequence: SET SPEED 9600, CONNECT, login, start'
  218.     db ' remote Kermit,',cr,lf
  219.     db '  put it into Server mode, escape back with Control-$'
  220. qckhlp3    db ' C, transfer'
  221.     db ' files with',cr,lf
  222.     db '  SEND x.txt, GET b.txt, BYE. Read more about it in "Using MS-DOS'
  223.     db ' Kermit".'
  224.     db cr,lf
  225.     db ' - more -  Press the space bar for a functional summary of '
  226.     db 'Kermit commands. $'
  227.  
  228. qckhlp5    db    cr,lf,lf,lf,' MS-DOS Kermit commands, a functional summary:'
  229.     db    cr,lf
  230.     db    cr,lf,' Local file management:         '
  231.     db    'Kermit program management:'
  232.     db    cr,lf,'   DIR    (list files)          '
  233.     db    '  EXIT     (from Kermit, return to DOS)'
  234.     db    cr,lf,'   CD     (change directory)    '
  235.     db    '  QUIT     (same as EXIT)'
  236.     db    cr,lf,'   DELETE (delete files)        '      
  237.     db    '  TAKE     (execute Kermit commands from file)'
  238.     db    cr,lf,'   RUN    (a DOS command)       '
  239.     db    '  CLS      (clear screen)'
  240.     db    cr,lf,'   TYPE   (display a file)      '
  241.     db    '  PUSH     (enter DOS, EXIT returns to Kermit)'
  242.     db    cr,lf,'   SPACE  (show disk space)     '
  243.     db    '  Ctrl-C   (interrupt a command)'
  244.     db    cr,lf
  245.     db    cr,lf,' Communication settings:        '
  246.     db    'Terminal emulation:'
  247.     db    cr,lf,'   SET PORT, SET SPEED          '
  248.     db    '  CONNECT  (begin terminal emulation)'
  249.     db    cr,lf,'   SET PARITY                   '
  250.     db    '  HANGUP   (close connection)'
  251.     db    cr,lf,'   SET FLOW-CONTROL             '
  252.     db    '  Alt-X    (return to MS-Kermit> prompt)'
  253.     db    cr,lf,'   SET LOCAL-ECHO               '
  254.     db    '  SET KEY  (key mapping)'
  255.     db    cr,lf,'   SET ? to see others          '
  256.     db    '  SET TERMINAL TYPE, BYTESIZE, other parameters'
  257.     db    cr,lf,'   SHOW COMMUNICATIONS, MODEM   '
  258.     db    '  SHOW TERMINAL, SHOW KEY'
  259.     db    cr,lf,lf,' - more -$'
  260. qckhlp6    db    cr,'          '
  261.     db    cr,lf,' File transfer settings:        '
  262.     db    cr,lf,'   SET FILE CHARACTER-SET name  '  
  263.     db    '  SET TRANSFER CHARACTER-SET'
  264.     db    cr,lf,'   SET FILE TYPE TEXT, BINARY   '  
  265.     db    '  SET SEND or RECEIVE parameters'
  266.     db    cr,lf,'   SET FILE ? to see others     '  
  267.     db    '  SET WINDOWS (sliding windows)'
  268.     db    cr,lf,'   SHOW FILE                    '  
  269.     db    '  SHOW PROTOCOL, SHOW STATISTICS'
  270.     db    cr,lf
  271.     db    cr,lf,' Kermit file transfer:           '
  272.     db    'ASCII file transfer:'
  273.     db    cr,lf,'   SEND files (to RECEIVE)      '
  274.     db    '  LOG SESSION, CLOSE SESSION (download)'
  275.     db    cr,lf,'   RECEIVE    (from SEND)       '
  276.     db    '  TRANSMIT (upload)'
  277.     db    cr,lf,'   MAIL files (to RECEIVE)      '
  278.     db    '  SET TRANSMIT parameters'
  279.     db    cr,lf,lf,' - more - $'
  280. qckhlp7    db    cr,'          '
  281.     db    cr,lf,' Using a Kermit server:         '
  282.     db    'Being a kermit server:'
  283.     db    cr,lf,'   GET files    (from server)   '
  284.     db    '  SET SERVER TIMEOUT or LOGIN'
  285.     db    cr,lf,'   SEND or MAIL   (to server)   '
  286.     db    '  ENABLE or DISABLE features'
  287.     db    cr,lf,'   REMOTE command (to server)   '
  288.     db    '  SERVER'
  289.     db    cr,lf,'   FINISH, LOGOUT, BYE          '
  290.     db    '  SHOW SERVER'
  291.     db    cr,lf
  292.     db    cr,lf,' Script programming commands:   '
  293.     db    cr,lf,'   INPUT, REINPUT secs text     '
  294.     db    '  :label, GOTO label'
  295.     db    cr,lf,'   OUTPUT text                  '
  296.     db    '  IF [ NOT ] condition command'
  297.     db    cr,lf,'   ASK or ASKQ variable prompt  '
  298.     db    '  OPEN READ (or WRITE or APPEND) file'
  299.     db    cr,lf,'   DEFINE variable or macro     '
  300.     db    '  READ variable-name'
  301.     db    cr,lf,'   ASSIGN variable or macro     '
  302.     db    '  WRITE file-designator text'
  303.     db    cr,lf,'   [ DO ] macro arguments       '
  304.     db    '  CLOSE READ or WRITE file or logfile'
  305.     db    cr,lf,'   ECHO text                    '
  306.     db    '  END or POP from macro or file'
  307.     db    cr,lf,'   PAUSE time                   '
  308.     db    '  STOP all macros and command files'
  309.     db    cr,lf,'   WAIT time modem-signals      '
  310.     db    '  WRITE file-designator text'
  311.     db    cr,lf,'   SHOW SCRIPTS, SHOW MACROS    '
  312.     db    '  SHOW VARIABLES'
  313.     db    cr,lf,lf
  314.     db ' Use "?" within comands for help on what fits that word.',lf,'$'
  315. data1    ends
  316.  
  317. data    segment
  318.  
  319. comtab  db    64            ; COMND tables
  320.     mkeyw    'Asg',assign        ; synonym
  321.     mkeyw    'Ask',ask
  322.     mkeyw    'Askq',askq
  323.     mkeyw    'Assign',assign
  324.     mkeyw    'Bye',bye
  325.     mkeyw    'C',telnet
  326.     mkeyw    'CD',cwdir
  327.     mkeyw    'Clear',scclr
  328.     mkeyw    'Close',clscpt
  329.     mkeyw    'Comment',comnt
  330.     mkeyw    'Connect',telnet
  331.     mkeyw    'CLS',cls
  332.     mkeyw    'CWD',cwdir
  333.     mkeyw    'Define',dodef
  334.     mkeyw    'Delete',delete
  335.     mkeyw    'Directory',direct
  336.     mkeyw    'Disable',srvdsa
  337.     mkeyw    'Do',docom
  338.     mkeyw    'Echo',scecho
  339.     mkeyw    'Enable',srvena
  340.     mkeyw    'End',popcmd
  341.     mkeyw    'Exit',exit
  342.     mkeyw    'Finish',finish
  343.     mkeyw    'Get',get
  344.     mkeyw    'goto',goto
  345.     mkeyw    'H',help
  346.     mkeyw    'Hangup',dtrlow
  347.     mkeyw    'Help',help
  348.     mkeyw    'If',ifcmd
  349.     mkeyw    'I',scinp
  350.     mkeyw    'Input',scinp
  351. ;;;    mkeyw    'Load',load
  352.     mkeyw    'Log',setcpt
  353.     mkeyw    'Logout',logout
  354.     mkeyw    'Mail',mail
  355.     mkeyw    'Open',vfopen
  356.     mkeyw    'Output',scout
  357.     mkeyw    'Pause',scpau
  358.     mkeyw    'Pop',popcmd
  359.     mkeyw    'Push',dopush
  360.     mkeyw    'Quit',exit
  361.     mkeyw    'R',read
  362.     mkeyw    'Read',vfread
  363.     mkeyw    'Receive',read
  364.     mkeyw    'Reinput',screinp
  365.     mkeyw    'Remote',remote
  366.     mkeyw    'Replay',replay
  367.     mkeyw    'Run',run
  368.     mkeyw    'S',send
  369.     mkeyw    'Send',send
  370.     mkeyw    'Server',server
  371.     mkeyw    'Set',setcom
  372.     mkeyw    'Show',showcmd
  373.     mkeyw    'Space',chkdsk
  374.     mkeyw    'Status',status
  375.     mkeyw    'Stay',stay
  376.     mkeyw    'Stop',takeqit
  377.     mkeyw    'Take',take
  378.     mkeyw    'Transmit',scxmit
  379.     mkeyw    'Type',typec
  380.     mkeyw    'Version',prvers
  381.     mkeyw    'Wait',scwait
  382.     mkeyw    'Write',write
  383.     mkeyw    ':',comnt        ; script labels, do not react
  384.     mkeyw    'Patch',patch
  385.  
  386. shotab    db    14            ; SHOW keyword
  387.     mkeyw    'Communications',shcom
  388.     mkeyw    'File',shfile
  389.     mkeyw    'Key',shokey
  390.     mkeyw    'Logging',shlog
  391.     mkeyw    'Macros',shomac
  392.     mkeyw    'Memory',shmem
  393.     mkeyw    'Modem',shomodem
  394.     mkeyw    'Protocol',shpro
  395.     mkeyw    'Scripts',shscpt
  396.     mkeyw    'Server',shserv
  397.     mkeyw    'Statistics',shosta
  398.     mkeyw    'Terminal',shterm
  399.     mkeyw    'Translation',shorx
  400.     mkeyw    'Variables',shovar
  401.                     ; Kermit initing from Environment
  402. nulprmpt db    0            ; null prompt
  403. initab    db    6            ; Environment phrase dispatch table
  404.     mkeyw    'INPUT-buffer-length',setinpbuf ; Script INPUT buffer length
  405.     mkeyw    'Rollback',setrollb    ; number of Terminal rollback screens
  406.     mkeyw    'COM1',com1port
  407.     mkeyw    'COM2',com2port
  408.     mkeyw    'COM3',com3port
  409.     mkeyw    'COM4',com4port
  410. patched    db    1        ; 1 = enable patching; 0 = disable or done
  411.  
  412.     even
  413. lclsusp    dw    0        ; address of routine to call when going to DOS
  414. lclrest    dw    0        ; address of routine to call when returning
  415. lclexit    dw    0        ; address of routine to call when exiting
  416. tcptos    dw    0        ; top of stack for TCP code
  417. ssave    dd    0        ; Original SS:SP when doing Command.com
  418. in3ad    dw    0,0        ; Original break interrupt addresses
  419. ceadr    dd    0        ; DOS Critical Error interrupt address
  420. orgcbrk    db    0        ; original Control-Break Check state
  421. psp    dw    0        ; segment of Program Segment Prefix
  422. exearg    dw    0        ; segment addr of environment (filled in below)
  423.     dd    0        ; ptr to cmd line (filled in below)
  424.     dw    5ch,0,6ch,0    ; our def fcb's; segment filled in later
  425. dosnum    dw    0        ; dos version number, major=low, minor=high
  426. dosctty    db    0        ; !=0 if DOS attempts using our comms line
  427. curdsk    db    0        ; Current disk
  428. origd    db    0        ; Original disk
  429. orgdir    db    64 dup (0)    ; original directory on original disk
  430. taklev    db    0        ; Take levels
  431. oldtak    db    0        ; Take level at start of command parse
  432. takadr    dw    takstr-(size takinfo) ; Pointer into structure
  433. takstr    db    (size takinfo) * maxtak dup(?)
  434. filtst    filest    <>        ; file structure for procedure isfile
  435. maxtry    db    defmxtry    ; Retry limit for data packet send/rcv
  436. ininm2    db    'MSKERMIT.INI',0 ; init file name for 2.0
  437. ptchnam    db    'MSKERMIT.PCH',0 ; patch file name
  438. delcmd    db    ' del ',0    ; delete command
  439. dircmd    db    ' dir ',0    ; directory command
  440. typcmd    db    ' type ',0    ; type command
  441. kerenv    db    'KERMIT=',0,0    ; Kermit= environment variable, + 2 nulls
  442. pthnam    db    'PATH='        ; Path environment variable
  443. pthlen    equ    $-pthnam    ;  length of that string
  444. pthadr    dw    0        ; offset of PATH= string
  445.  
  446. slashc    db    ' /c '        ; slashc Must directly preceed tmpbuf
  447. tmpbuf    db    128 dup (0)    ; temp space for file names and comments
  448. cmspnam    db    'COMSPEC='    ; Environment variable
  449. cmsplen    equ    $-cmspnam
  450. cmspbuf    db    '\command.com',30 dup (0) ; default name plus additional space
  451. shellnam db    'SHELL='    ; Environment variable
  452. shellen    equ    $-shellnam
  453. shellbuf db    40 dup (0)    ; buffer for name
  454. eexit    db    cr,'exit',cr
  455. leexit    equ    $-eexit
  456. onexit    db    7,0,'ON_EXIT'    ; <length>on_exit macro name
  457. onexlen    equ    $-onexit-2    ; length of name
  458. mfmsg    db    '?Not enough memory to run Kermit$'
  459. mf7msg    db    '?Attempted to allocate a corrupted memory area$'
  460. spcmsg    db    ' bytes available on drive '
  461. spcmsg1    db    ' :',cr,lf,0
  462. spcmsg2    db    cr,lf,' Drive '
  463. spcmsg3    db    ' : is not ready',0
  464. errlev    db    0        ; DOS errorlevel to be returned
  465. kstatus    dw    0        ; command execution status (0 = success)
  466. thsep    db    0        ; thousands separator
  467. tdfmt    db    0        ; date/time format code
  468. totpar    dw    0
  469. temp    dw    0
  470.  
  471. segstr    db    'ABCDEFG'    ; segment "names" for patcher
  472. lsegstr    equ    $-segstr
  473.     even
  474. segtab    dw    code        ; segment values for patcher
  475.     dw    code1
  476.     dw    code2
  477.     dw    data
  478.     dw    data1
  479.     dw    _TEXT
  480.     dw    dgroup
  481.  
  482. exmacptr dw    offset exmacro,seg exmacro
  483. psetint    dw    offset setint,seg setint
  484. data   ends
  485.  
  486. code    segment
  487.     extrn    logout:near, mail:near, load:near, shovar:near
  488.     extrn    bye:near, telnet:near, finish:near, comnd:near, prompt:near
  489.     extrn    read:near, remote:near, send:near, status:near, get:near
  490.     extrn    serrst:near, setcom:near, dtrlow:near, cmblnk:near
  491.     extrn    clscpi:near, clscpt:near, scpini:near, setrollb:near
  492.     extrn    dodef:near, setcpt:near, docom:near, shomodem:near
  493.     extrn    server:near, lclini:near, shokey:near, shomac:near, shosta:near
  494.     extrn    strlen:near, strcpy:near, shserv:near, initibm:near
  495.     extrn    strcat:near, prtasz:near, shorx:near, lnout:near, lnouts:near
  496.     extrn    scout:near,scinp:near,scpau:near,scecho:near,scclr:near
  497.     extrn    scxmit:near, scwait:near, srvdsa:near, srvena:near
  498.     extrn    shcom:near, shlog:near, shpro:near, shterm:near, shscpt:near
  499.     extrn    shfile:near, takopen:near, takclos:near, ask:near, askq:near
  500.     extrn    assign:near, goto:near, screinp:near, ifcmd:near, write:near
  501.     extrn    setinpbuf:near, shmem:near, replay:near, atoi:near
  502.     extrn    katoi:near, com1port:near, com2port:near, com3port:near,
  503.     extrn    com4port:near, popcmd:near, mprompt:near, locate:near
  504.     extrn    vfopen:near, vfread:near
  505.  
  506.         assume  cs:code, ds:data, ss:_stack, es:nothing
  507.  
  508. START    PROC    FAR
  509.     mov    ax,data            ; initialize DS
  510.         mov    ds,ax
  511.     mov    psp,es            ; remember psp address
  512.     mov    ah,dosver        ; get DOS version number (word)
  513.     int    dos
  514.     xchg    ah,al            ; major version to ah
  515.     mov    dosnum,ax        ; remember dos version
  516.     cmp    ax,200h            ; earlier than DOS 2.0?
  517.     jge    start1            ; ge = no
  518.     mov    ah,prstr
  519.     mov    dx,offset erms34    ; complain
  520.     int    dos
  521.     push    psp            ; set up exit for DOS 1
  522.     xor    ax,ax            ; and the IP
  523.     push    ax            ; make return addr of psp:0 for DOS 1
  524.     ret                ; and return far to exit now
  525. start1:
  526.     call    memini            ; initialize our memory usage
  527.     mov    ah,setdma        ; set disk transfer address
  528.     mov    dx,offset buff
  529.     int    dos
  530.  
  531.     call    dword ptr psetint    ; ^C, DOS critical error interrupts
  532.     mov    ah,gcurdsk        ; get current disk
  533.     int    dos
  534.     inc    al            ; make 1 == A (not zero)
  535.     mov    curdsk,al
  536.     mov    origd,al        ; remember original disk we started on
  537.     mov    si,offset orgdir     ; place for directory path w/o drive code
  538.     add    al,'A'-1        ; make al alphabetic disk drive again
  539.     mov    [si],al            ; put it into original path descriptor
  540.     inc    si
  541.     mov    byte ptr [si],':'    ; add drive specifier too
  542.     inc    si
  543.     mov    byte ptr [si],'\'    ; add root indicator as well
  544.     inc    si
  545.     mov    ah,gcd            ; get current directory (path really)
  546.     xor    dl,dl            ; use current drive
  547.     int    dos
  548.     call    getpath            ; get the path from the environment
  549.     call    gettsep            ; get thousands separator, t/date code
  550.     mov    ah,gswitch
  551.     xor    al,al            ; pick up switch character
  552.     int    dos
  553.     mov    slashc+1,dl
  554.     and    maxtry,3fh        ; limit # packet retries
  555.     call    getcsp            ; get comspec from environment
  556.     call    getssp            ; get shellspec from environment
  557.     call    getparm            ; read "KERMIT=" Environment line
  558.     jc    start1b            ; c = fatal error
  559.     xor    cl,cl            ; counter, starts at 0
  560. start1a:mov    bx,offset kerenv+6    ; append "<digit>="  to "KERMIT"
  561.     mov    [bx],cl            ; binary digit
  562.     inc    cl
  563.     add    byte ptr [bx],'0'    ; to ascii
  564.     mov    byte ptr [bx+1],'='    ; append equals sign
  565.     call    getparm            ; read "KERMITn=" Environment line
  566.     jc    start1b            ; c = fatal error
  567.     cmp    cl,9            ; done all digits?
  568.     jbe    start1a            ; be = no
  569.                     ;
  570.     call    scpini            ; initialize script routines
  571.     jc    start1b            ; c = fatal error
  572.     call    lclini            ; do local initialization
  573.     cmp    flags.extflg,0        ; exit now?
  574.     je    start2            ; e = no
  575. start1b:mov    ah,prstr        ; announce our premature exit
  576.     mov    dx,offset ermes5    ; can't complete initialization
  577.     int    dos
  578.     jmp    krmend            ; quit immediately
  579. start2:    mov    word ptr comand.cmrprs,offset krmend ; offset of reparse addr
  580.     mov    ax,cs            ; our current code segment
  581.     mov    word ptr comand.cmrprs+2,ax ; segment of reparse address
  582.     mov    comand.cmostp,sp    ; save for reparse too
  583.     call    gcmdlin            ; read command line
  584.     cmp    taklev,0        ; in a Take file?
  585.     jne    start3            ; ne = yes, skip help msg
  586.     mov    ah,prstr
  587.     mov    dx,offset machnam    ; display machine name
  588.     int    dos
  589.         mov    dx,offset verident    ; display version header
  590.         int    dos
  591.     mov    dx,offset copyright    ; display copyright notice
  592.     int    dos
  593.     mov    dx,offset hlpmsg
  594.     int    dos
  595. start3:    call    serrst            ; reset serial port (if active)
  596.     call    initibm            ; define IBM macro
  597.     call    rdinit            ; read kermit init file
  598.  
  599.  ; This is the main KERMIT loop.  It prompts for and gets the users commands
  600.  
  601. kermit:    mov    ax,ds
  602.     mov    es,ax            ; convenient safety measure
  603.     mov    dx,prmptr        ; get prompt string address
  604.     call    mprompt              ; set master reparse address to here
  605.     cmp    flags.cxzflg,'C'    ; did someone want out?
  606.     jne    kermt9            ; ne = no
  607. kermt8:    cmp    taklev,0        ; are we in a Take file?
  608.     je    kermt9            ; e = no, ignore the signal
  609.     call    takclos            ; close take file, release buffer
  610.     jmp    short kermt8        ; close any other take files
  611. kermt9:    mov    flags.cxzflg,0        ; reset each time
  612.     and    flags.remflg,not dserver ; turn off server mode bit
  613.     cmp    dosctty,0        ; is DOS using our comms line?
  614.     je    kermt1            ; e = no
  615.     and    flags.remflg,not(dquiet+dregular+dserial)
  616.     or    flags.remflg,dquiet    ; set display to quiet mode
  617.     call    serrst            ; close port so CTTY can run
  618. kermt1:    mov    dx,offset comtab
  619.     mov    bx,offset tophlp
  620.     cmp    flags.extflg,0        ; exit flag set?
  621.     jne    krmend            ; ne = yes, jump to KRMEND
  622.     mov    comand.cmcr,1        ; allow bare CR's
  623.         mov    ah,cmkey
  624.     mov    comand.impdo,1        ; allow implied "DO macro"
  625.     call    comnd
  626.     jc    kermt3            ; c = failure
  627.     mov    comand.impdo,0        ; only on initial keyword, not here
  628.     mov    comand.cmcr,0        ; no more bare CR's
  629.     call    bx                  ; call the routine returned in BX
  630.     jc    kermt3            ; c = failure
  631.     cmp    flags.extflg,0        ; exit flag set?
  632.     jne    krmend            ; ne = yes, jump to KRMEND
  633.     jmp    short kermt5        ; do idle loop cleanup
  634.  
  635. kermt3:    cmp    flags.cxzflg,'C'    ; got here via Control-C?
  636.     jne    kermt7            ; ne = no
  637.     cmp    flags.extflg,0        ; exit flag set?
  638.     jne    kermt5            ; ne = yes, skip msg, do cleanup
  639.     mov    dx,offset ermes3    ; say command not executed
  640.     mov    ah,prstr        ; print    the error message in dx
  641.     int    dos
  642. kermt5:    cmp    flags.cxzflg,'C'    ; user Control-C abort?
  643.     jne    kermt7            ; ne = no, do normal operations
  644.     cmp    taklev,0        ; in a Take file?
  645.     je    kermt7            ; e = no        
  646.     call    takclos            ; close take file, release buffer
  647.     jmp    short kermt5        ; close any other take files
  648. kermt7:    cmp    flags.extflg,0        ; exit flag set?
  649.     jne    krmend            ; ne = yes, exit
  650.     jmp    kermit            ; e = no, get next command
  651.  
  652. krmend:cmp    taklev,0        ; in a Take file?
  653.     je    krmend2a        ; e = no        
  654.     call    takclos            ; close take file, release buffer
  655.     jmp    short krmend        ; close any other take files
  656. krmend2a:call    dword ptr exmacptr    ; find on_exit macro
  657.     jc    krmend2c        ; c = not found
  658.                     ; perform ON_EXIT macro
  659. krmend2b:cmp    taklev,0        ; finished with macros?
  660.     je    krmend2c        ; e = yes
  661.     mov    dx,prmptr        ; get prompt string address
  662.     call    mprompt              ; set master reparse address to here
  663.     mov    flags.cxzflg,0        ; reset each time
  664.     and    flags.remflg,not dserver ; turn off server mode bit
  665.     mov    dx,offset comtab    ; keyword table
  666.     xor    bx,bx            ; no help
  667.         mov    ah,cmkey
  668.     mov    comand.impdo,1        ; allow implied "DO macro"
  669.     mov    comand.cmcr,1        ; allow bare CR's
  670.     call    comnd
  671.     jc    krmend2c        ; c = failure
  672.     mov    comand.impdo,0        ; only on initial keyword, not here
  673.     call    bx            ; call the routine returned in BX
  674.     jnc    krmend2b        ; nc = success, keep doing commands
  675. krmend2c:                ; end of ON_EXIT macro processing
  676.     call    serrst            ; just in case the port wasn't reset
  677.     call    clscpi            ; close log files
  678.     mov    bx,lclexit        ; addr of sys dependent exit routine
  679.     or    bx,bx            ; sys dependent routines want service?
  680.     jz    krmend3            ; z = no
  681.     call    bx            ; call it
  682. krmend3:mov    dl,origd        ; original disk drive
  683.     dec    dl            ; want A == 0
  684.     mov    ah,seldsk        ; reset original disk just in case
  685.     int    dos
  686.     mov    dx,offset orgdir    ; restore original directory
  687.     mov    ah,chdir
  688.     int    dos
  689.     push    ds            ; save ds around these DOS calls
  690.     mov    ax,cs            ; compose full address of ^C routine
  691.     mov    ds,ax            ; segment is the code segment
  692.     mov    dx,offset in3ad        ; restore Control-C interrupt vector
  693.     mov    al,23H            ; interrupt 23H
  694.     mov    ah,25H            ; set interrupt vector
  695.     int    dos            ; ah, that's better
  696.     mov    dx,offset ceadr        ; DOS's Critical Error handler
  697.     mov    al,24h            ; interrupt 24h
  698.     mov    ah,25h            ; do replacement (put it back)
  699.     int    dos
  700.     pop    ds
  701.     call    cbrestore        ; restore state of Control-Break Chk
  702.     mov    ah,4cH            ; terminate process
  703.     mov    al,errlev        ; return error level
  704.     int    dos
  705.     ret
  706. START    ENDP
  707.  
  708. ; This is the 'EXIT' command.  It leaves KERMIT and returns to DOS
  709.  
  710. EXIT    PROC    NEAR
  711.     mov    ah,cmeol
  712.     call    comnd            ; get a confirm
  713.     jc    exit1            ; c = failure
  714.     mov    flags.extflg,1        ; set the exit-Kermit flag
  715. exit1:    ret
  716. EXIT    ENDP
  717. code    ends
  718.  
  719. code1    segment
  720.     assume    cs:code1
  721. exmacro    proc    far            ; perform on_exit() macro
  722.     push    bx
  723.     push    cx
  724.     push    si
  725.     mov    bx,offset mcctab    ; table of macro names
  726.     mov    cl,[bx]            ; number of names in table
  727.     xor    ch,ch
  728.     jcxz    exmacx            ; z = empty table, do nothing
  729.     inc    bx            ; point to length of first name
  730. exmac2:    mov    ax,[bx]            ; length of this name
  731.     cmp    ax,onexlen        ; length same as desired keyword?
  732.     jne    exmac3            ; ne = no, search again
  733.     mov    si,bx
  734.     add    si,2            ; point at first char of name
  735.     push    cx            ; save name counter
  736.     push    di            ; save reg
  737.     mov    cx,onexlen        ; length of name
  738.     mov    di,offset onexit+2    ; point at desired macro name text
  739.     push    es            ; save reg
  740.     push    ds
  741.     pop    es            ; make es use data segment
  742.     cld
  743.     repe    cmpsb            ; match strings
  744.     pop    es            ; need current si below
  745.     pop    cx
  746.     pop    di            ; recover saved regs
  747.     jne    exmac3            ; ne = no match
  748.     mov    onexit+2,0        ; change name to be invisible
  749.     mov    byte ptr [bx+2],0    ; change macro table name too
  750.     jmp    short exmac4        ; e = matched
  751. exmac3:    add    bx,ax            ; step to next name, add name length
  752.     add    bx,4            ; + count and def word ptr
  753.     loop    exmac2            ; try next name
  754. exmacx:    pop    si            ; no macro, fail
  755.     pop    cx
  756.     pop    bx
  757.     stc                ; say failure
  758.     ret
  759.  
  760. exmac4:    cmp    taklev,maxtak        ; room in Take level?
  761.     jge    exmacx            ; ge = no, exit with no action
  762.     inc    taklev            ; increment take level
  763.     add    takadr,size takinfo    ; make a new Take entry/macro
  764.     mov    bx,takadr        ; point to current macro structure
  765.     mov    ax,ds            ; text is in our data seg
  766.     mov    [bx].takbuf,ax        ; seg of definition string struc
  767.     mov    [bx].takptr,offset onexit+2 ; where to read next command char
  768.     mov    [bx].takcnt,onexlen    ; number of chars in definition
  769.     mov    [bx].takargc,0        ; store macro argument count
  770.     mov    [bx].taktyp,0ffh    ; flag as a macro
  771.     pop    si
  772.     pop    cx
  773.     pop    bx
  774.     clc                ; say success
  775.     ret
  776. exmacro    endp
  777. code1    ends
  778.  
  779. code    segment
  780.     assume    cs:code
  781. ; TAKE commands    from a file, and allow a path name
  782. TAKE    PROC    NEAR
  783.     mov    kstatus,kssuc        ; global status, success
  784.     cmp    taklev,maxtak        ; at the limit?
  785.     jl    take1            ; l = no
  786.     mov    ah,prstr
  787.     mov    dx,offset erms30    ; complain
  788.     int    dos
  789.     stc                ; failure
  790.     ret
  791. take1:    mov    dx,offset tmpbuf    ; work buffer
  792.     mov    tmpbuf,0
  793.     mov    bx,offset filmsg    ; Help in case user types "?"
  794.     mov    comand.cmkeep,1        ; keep file open
  795.     mov    ah,cmword        ; get file name
  796.     call    comnd
  797.     jc    take1a            ; c = failure
  798.     mov    ah,cmeol
  799.     call    comnd
  800.     jc    take1a            ; c = failure
  801.     mov    ax,offset tmpbuf    ; point to name again
  802.     cmp    tmpbuf,0        ; empty filespec?
  803.     jne    take2            ; ne = no
  804.     mov    ah,prstr
  805.     mov    dx,offset ermes1    ; say more parameters needed
  806.     int    dos
  807.     stc
  808. take1a:    ret
  809.                     ; TAKE2: enter with ax=filename ptr
  810. TAKE2:    call    spath            ; is it around?
  811.     jc    take3            ; no, go complain
  812.     mov    dx,ax            ; point to name from spath
  813.     mov    ah,open2        ; open file
  814.     xor    al,al            ; 0 = open for reading
  815.     cmp    dosnum,300h        ; at or above DOS 3?
  816.     jb    take2a            ; b = no, so no shared access
  817.     or    al,40h            ; open for reading, deny none
  818. take2a:    int    dos
  819.     jnc    take4            ; nc = opened ok, keep going
  820.     mov    ax,dx            ; recover filename pointer
  821. take3:    push    ax
  822.     mov    ah,prstr
  823.     mov    dx,offset erms31
  824.     int    dos
  825.     pop    ax
  826.     mov    dx,ax            ; asciiz file name
  827.     call    prtasz            ; display it
  828.     mov    kstatus,kstake        ; status, Take failed
  829.     clc                ; we've done all error displays
  830.     ret
  831.                     ; TAKE4: enter with ax=filename ptr
  832. TAKE4:    call    takopen            ; open take buffer in macro space
  833.     jc    take6            ; c = failure
  834.     push    bx
  835.     mov    bx,takadr        ; get current frame ptr
  836.     mov    [bx].takhnd,ax        ; save file handle
  837.     mov    [bx].taktyp,0feh     ; mark as 2.0 file handle
  838.     pop    bx
  839.     cmp    flags.takflg,0        ; echoing Take files?
  840.     je    take5            ; e = no
  841.     mov    ah,prstr
  842.     mov    dx,offset crlf
  843.     int    dos
  844. take5:    call    takrd            ; get a buffer full of data
  845.     clc                ; success
  846. take6:    ret
  847. TAKE    ENDP
  848.  
  849. TAKRD    PROC    NEAR
  850.     push    ax
  851.     push    bx
  852.     push    cx    
  853.     push    dx
  854.     mov    bx,takadr
  855.     cmp    [bx].taktyp,0feh    ; get type of take (file?)
  856.     jne    takrd1            ; ne = no, do not read from disk
  857.     mov    cx,tbufsiz-2        ; # of bytes to read
  858.     mov    ax,[bx].takbuf        ; segment of Take buffer
  859.     push    bx            ; save frame address
  860.     mov    bx,[bx].takhnd        ; file handle is stored here
  861.     push    ds            ; save ds
  862.     mov    ds,ax            ; set ds to Take buffer segment
  863.     mov    dx,2            ; ds:dx = buffer, skip count word
  864.     mov    ah,readf2        ; read file
  865.     int    dos
  866.     pop    ds
  867.     pop    bx            ; restore frame address
  868.     jnc    takrd2            ; nc = successful read
  869. takrd1:    xor    ax,ax            ; error, say zero bytes read
  870. takrd2:    mov    [bx].takcnt,ax        ; number of bytes read
  871.     mov    [bx].takptr,2        ; offset of first new character
  872.     pop    dx
  873.     pop    cx
  874.     pop    bx
  875.     pop    ax
  876.     ret
  877. TAKRD    ENDP
  878.  
  879. ; TAKE-QUIT  (STOP)  Exit all Take files immediately but gracefully
  880.  
  881. TAKEQIT PROC    NEAR
  882.     mov    ah,cmeol
  883.     call    comnd
  884.     jnc    takqit1            ; nc = success
  885.     ret
  886. takqit1:xor    ch,ch
  887.     mov    cl,taklev        ; number of Take levels active
  888.     jcxz    takqit2            ; z = none
  889.     call    takclos            ; close current Take file
  890.     jmp    short takqit1        ; repeat until all are closed
  891. takqit2:clc                ; success
  892.     ret
  893. TAKEQIT    ENDP
  894.  
  895. ; put mskermit.ini onto take stack if it exists.  Just like
  896. ; the take command, except it doesn't read a filename
  897.  
  898. rdinit    proc    near            ; read kermit init file..
  899.     mov    ax,offset ininm2    ; default name to try
  900.     cmp    decbuf,0        ; alternate init file given?
  901.     je    rdini1            ; ne = no
  902.     mov    ax,offset decbuf    ; yes, use it
  903.     call    take2            ; let Take do error msgs
  904.     clc                ; force success
  905.     ret
  906. rdini1:    call    spath            ; is it around?
  907.     jc    rdini2            ; no, ignore file
  908.     mov    dx,ax            ; point to name from spath
  909.     mov    ah,open2        ; open file
  910.     xor    al,al            ; 0 = open for reading
  911.     cmp    dosnum,300h        ; at or above DOS 3?
  912.     jb    rdini1a            ; b = no, so no shared access
  913.     or    al,40h            ; open for reading, deny none
  914. rdini1a:int    dos
  915.     jc    rdini2            ; c = no ini file found, ignore
  916.     call    take4            ; use TAKE command to complete work
  917.     clc                ; ignore errors
  918. rdini2:    ret
  919. rdinit    endp
  920.  
  921. ; Patcher.  Patch file, MSKERMIT.PCH has the following format:
  922.  
  923. ; 301 \Xxxxx    Text to display upon successful patch load
  924. ; ;301 for V3.01.  For xxxx, see below
  925. ; ; optional comment lines may appear anywhere after the 1st
  926. ; ; xxxx in 1st line = total paragraphs in memory image.  Use \X if hex.
  927. ; DS:xxxx xx xx        ; optional comment.  DS (or CS) are case insensitive
  928. ; CS:xxxx xx xx xx    ; locations must be 4 hex chars, contents must be 2
  929. ;
  930. ; The 1st xx is the original value of the 1st byte @seg:offset for comparison.
  931. ; A 00 value says don't compare.  Subsequent xx's are replacement bytes.
  932. ; CS & DS lines may be intermixed.  AS & BS segments may be used when some
  933. ; external module sets words aseg & bseg to a seg-base.
  934. ; This mechanism expects file msscmd.obj to be linked first.
  935.  
  936. PATCH    proc
  937.     mov    ah,cmeol    ; confirm please
  938.     call    comnd
  939.     jc    patch1        ; c = no confirm
  940.     xor    ax,ax
  941.     xchg    al,patched    ; clear and test patched
  942.     test    al,al
  943.     jz    patch1        ; z = disabled or done
  944.     xchg    ah,flags.takflg    ; clear take flag -- don't echo patches
  945.     mov    byte ptr temp,ah; but save it
  946.     call    ptchr
  947.     mov    al,byte ptr temp; restore take flag
  948.     mov    flags.takflg,al
  949.     jc    patch2        ; c = NG
  950. patch1:    ret
  951.  
  952. patch2:    mov    dx,offset ermes8; Fatal error
  953.     mov    ah,prstr
  954.     int    dos
  955.     jmp    krmend        ; force exit
  956.  
  957. ptchr:    mov    ax,offset ptchnam ; point to name of patch file
  958.     call    rdini1        ; let rdini try to find it & do take stuff
  959.     jnc    ptch1        ; nc = file mskermit.pch was found
  960.     mov    dx,offset ermes7 ; say file not found
  961.     mov    ah,prstr
  962.     int    dos
  963.     clc
  964.     ret
  965.  
  966. ptch1:    mov    al,taklev    ; remember initial take level
  967.     mov    tmpbuf,al    ; when it changes, it's EOF & we're done
  968.     mov    comand.cmcr,1    ; bare cr's ok, to prevent prserr @EOF
  969.     call    ptchrl        ; read 1st line's 1st 'word'
  970.     jc    ptch2        ; c = trouble
  971.     jz    ptch3        ; z = EOF
  972.     mov    si,offset tmpbuf+1
  973.     call    atoi        ; convert version string to integer
  974.     jc    ptch2        ; c = bad number, or none
  975.     cmp    ax,version    ; does it match this version?
  976.     je    ptch4        ; e = yes
  977. ptch2:    mov    al,tmpbuf    ; if take level has changed,
  978.     xor    al,taklev    ;  we're already out of patch file
  979.     jnz    ptch3        ; nz = change in take level
  980.     call    takclos        ; close patch file
  981. ptch3:    mov    dx,offset ermes6
  982.     mov    ah,prstr    ; issue warning msg
  983.     int    dos
  984.     clc
  985.     ret
  986.  
  987. ptch4:    mov    dx,offset tmpbuf+1
  988.     call    ptchrw        ; read 2nd "word", 1st line
  989.     jc    ptch2        ; c = NG
  990.     mov    si,offset tmpbuf+1
  991.     call    katoi        ; convert 2nd "magic number"
  992.     jc    ptch2        ; c = NG
  993.     cmp    ax,totpar    ; is it the total paragraphs memini computed?
  994.     jne    ptch2        ; ne = no
  995.     mov    bx,offset buff    ; place to stash 1st lines patch/version msg
  996.     xor    dx,dx
  997.     mov    ah,cmline    ; read it
  998.     call    comnd
  999.  
  1000. ptch5:    call    ptchrl        ; read CS:xxxx or DS:xxxx
  1001.     jc    ptch6
  1002.     jz    ptch7        ; z = EOF
  1003.     cmp    ah,7        ; were 7 chars read?
  1004.     jne    ptch6        ; ne = no
  1005.     mov    si,offset tmpbuf+1
  1006.     and    word ptr[si],not 2020h ; convert to upper case
  1007.     cld
  1008.     lodsb            ; get the seg char
  1009.     cmp    word ptr[si],':S' ; S:, actually
  1010.     je    ptch8        ; e = ok
  1011. ptch6:    stc            ; error exit
  1012.     ret
  1013.  
  1014. ptch7:    clc
  1015.     ret
  1016.  
  1017. ptch8:    push    ds
  1018.     pop    es
  1019.     mov    di,offset segstr
  1020.     mov    cx,lsegstr    ; search for seg char in segstr
  1021.     repne    scasb
  1022.     jne    ptch6        ; ne = not found
  1023.     sub    di,offset segstr+1 ; distance spanned
  1024.     shl    di,1        ; make a word index
  1025.     mov    bx,segtab[di]    ; bx = seg-base
  1026.     or    bx,bx        ; seg-base = 0, aren't enabled for patching
  1027.     jz    ptch6        ; z = 0, no patching
  1028.     mov    word ptr[si],'X\' ; put '\X' in front of hex for katoi
  1029.     call    katoi        ; convert location
  1030.     jc    ptch6        ; c= NG
  1031.     push    bx        ; save seg being patched
  1032.     push    ax        ; save location being patched
  1033.     mov    tmpbuf+64,0    ; clear replacement byte count
  1034. ptch9:    mov    dx,offset tmpbuf+4
  1035.     call    ptchrw        ; read replacement byte follwing '\X'
  1036.     jnc    ptch11        ; nc = OK
  1037. ptch10:    pop    ax        ; clean stack & error return
  1038.     pop    bx
  1039.     stc
  1040.     ret
  1041.  
  1042. ptch11:    or    ax,ax        ; EOL?
  1043.     jnz    ptch13        ; nz = no
  1044.     mov    si,offset tmpbuf+64
  1045.     cld
  1046.     lodsb            ; replacement byte count
  1047.     cmp    al,2        ; gotta be at least 2
  1048.     jb    ptch10        ; b = too few
  1049.     mov    cx,ax        ; replacement count
  1050.     pop    di        ; patch location
  1051.     pop    es        ; patch segment
  1052.     lodsb            ; al = comparison byte
  1053.     or    al,al        ; key value to ignore comparison?
  1054.     jz    ptch12        ; z = 0, yes
  1055.     cmp    byte ptr es:[di],al ; do read check on memory image
  1056.     jne    ptch6        ; ne = no match, fail now
  1057. ptch12:    dec    cx        ; adjust for comparison byte
  1058.     rep    movsb        ; make patch
  1059.     jmp    ptch5        ; loop to read next line
  1060.  
  1061. ptch13:    cmp    ah,2        ; 2 chars req'd for replacement byte
  1062.     jne    ptch10        ; ne = bad
  1063.     mov    si,offset tmpbuf+2 ; convert it
  1064.     call    katoi
  1065.     jc    ptch10        ; c = bad number or none
  1066.     mov    si,offset tmpbuf+64    ; --> replacement byte counted string
  1067.     inc    byte ptr[si]    ; bump count
  1068.     mov    bl,[si]
  1069.     xor    bh,bh
  1070.     mov    byte ptr[si+bx],al ; stash replacement byte
  1071.     jmp    short ptch9    ; loop for next byte
  1072.  
  1073. ptchrl:    mov    dx,offset crlf    ; read 1st "word", next line to tmpbuf+1
  1074.     call    prompt
  1075.     mov    dx,offset tmpbuf+1
  1076.     call    ptchrw
  1077.     jc    ptchrb        ; c = NG
  1078.     mov    al,tmpbuf
  1079.     xor    al,taklev
  1080.     jz    ptchra        ; z = not EOF
  1081.     xor    ax,ax        ; set z flag for EOF
  1082.     ret
  1083.  
  1084. ptchra:    or    ah,ah        ; empty or comment line?
  1085.     jz    ptchrl        ; z = empty or comment, ignore
  1086. ptchrb:    ret
  1087.  
  1088. ptchrw:    mov    ah,cmword
  1089.     mov    comand.cmper,1    ; prohibit substitution variable expansion
  1090.     xor    bx,bx        ; 'help' ptr
  1091.     call    comnd
  1092.     xchg    ah,al
  1093.     ret
  1094. PATCH    endp
  1095.  
  1096. ; Get command line into a Take macro buffer. Allow "-f filspec" to override
  1097. ; normal mskermit.ini initialization filespec, allow command "stay" to
  1098. ; suppress automatic exit to DOS at end of command line execution. [jrd]
  1099.  
  1100. gcmdlin    proc    near
  1101.     mov    word ptr decbuf,0    ; storage for new init filename
  1102.     push    es
  1103.     cld
  1104.     mov    es,psp            ; address psp
  1105.     xor    ch,ch
  1106.     mov    cl,es:byte ptr[cline]    ; length of cmd line from DOS
  1107.     jcxz    gcmdl1            ; z = empty line
  1108.     mov    si,cline+1        ; point to actual line
  1109. gcmdl0:    cmp    byte ptr es:[si],' '    ; skip over leading whitespace
  1110.     ja    gcmdl2            ; a = non-whitespace
  1111.     inc    si
  1112.     loop    gcmdl0            ; fall through on all whitespace
  1113. gcmdl1:    jmp    gcmdl14            ; common exit jump point
  1114. gcmdl2:    inc    cx            ; include DOS's c/r
  1115.     call    takopen            ; open take buffer in macro space
  1116.     mov    bx,takadr
  1117.     mov    byte ptr [bx].taktyp,0ffh ; mark as a macro
  1118.     mov    [bx].takcnt,0        ; length of text
  1119.     mov    es,[bx].takbuf        ; segment of buffer, from takopen
  1120.     mov    di,2            ; skip count word
  1121.     push    psp
  1122.     pop    ds            ; DS = PSP
  1123.     xor    dx,dx            ; clear brace count
  1124. gcmdl3:    or    cx,cx            ; anything left?
  1125.     jle    gcmdl10            ; le = no
  1126.     lodsb                ; get a byte from PSP's command line
  1127.     dec    cx            ; one less char in input string
  1128.     cmp    al,','            ; comma?
  1129.     jne    gcmdl4            ; no, keep going
  1130.     or    dx,dx            ; inside braces?
  1131.     jnz    gcmdl9            ; nz = yes, retain embedded commas
  1132.     mov    al,cr            ; convert to cr
  1133.     jmp    short gcmdl9        ; store it
  1134. gcmdl4:    call    bracechk        ; check for curly braces
  1135.     jc    gcmdl9            ; c = found and counted brace
  1136.     or    dx,dx            ; outside braces?
  1137.     jnz    gcmdl9            ; nz = no, ignore flag
  1138.     cmp    al,'-'            ; starting a flag?
  1139.     jne    gcmdl9            ; ne = no
  1140.     mov    ah,[si]            ; get flag letter
  1141.     or    ah,20h            ; convert to lower case
  1142.     cmp    ah,'f'            ; 'f' for init file replacement?
  1143.     jne    gcmdl9            ; ne = no
  1144.     inc    si            ; accept flag letter
  1145.     dec    cx
  1146. gcmdl5:    or    cx,cx            ; anything to read?
  1147.     jle    gcmdl10            ; le = exhausted supply
  1148.     lodsb                ; get filespec char from psp
  1149.     dec    cx            ; one less char in source buffer
  1150.     cmp    al,' '            ; in whitespace?
  1151.     jbe    gcmdl5            ; be = yes, scan it off
  1152.     dec    si            ; backup to real text
  1153.     inc    cx
  1154.                     ; copy filspec to buffer decbuf
  1155.     push    es            ; save current destination pointer
  1156.     push    di            ;  which is in es:di (Take buffer)
  1157.     mov    di,data            ; set es:di to regular decbuf
  1158.     mov    es,di
  1159.     lea    di,decbuf        ; where filespec part goes
  1160.     mov    word ptr es:[di],0    ; plant safety terminator
  1161. gcmdl6:    lodsb                ; get filespec char
  1162.     dec    cx            ; one less available
  1163.     cmp    al,' '            ; in printables?
  1164.     jbe    gcmdl7            ; be = no, all done
  1165.     cmp    al,','            ; comma command separator?
  1166.     je    gcmdl7            ; e = yes, all done
  1167.     stosb                ; store filespec char
  1168.     or    cx,cx            ; any chars left?
  1169.     jg    short gcmdl6        ; g = yes
  1170. gcmdl7:    mov    byte ptr es:[di],0    ; end filespec on a null
  1171.     pop    di            ; recover destination pointer es:di
  1172.     pop    es
  1173. gcmdl8:    or    cx,cx            ; strip trailing whitespace
  1174.     jle    gcmdl10            ; le = nothing left
  1175.     lodsb
  1176.     dec    cx
  1177.     cmp    al,' '            ; white space?
  1178.     jbe    gcmdl8            ; be = yes, strip it
  1179.     cmp    al,','            ; at next command?
  1180.     je    gcmdl10            ; e = yes, skip our own comma
  1181.     dec    si            ; back up to reread the char
  1182.     inc    cx
  1183.     jmp    gcmdl3            ; read more command text
  1184.                     ; end of flag analysis
  1185. gcmdl9:    stosb                ; deposit most recent char
  1186. gcmdl10:or    cx,cx            ; anything left to read?
  1187.     jg    gcmdl3            ; g = yes, loop
  1188.                     ;
  1189.     mov    ax,data            ; restore segment registers
  1190.     mov    ds,ax
  1191.     mov    si,[bx].takbuf        ; get segment of Take buffer
  1192.     mov    es,si
  1193.     mov    si,2            ; skip count word
  1194.     mov    cx,di            ; current end pointer, (save di)
  1195.     sub    cx,si            ; current ptr minus start offset
  1196.     mov    [bx].takcnt,cx        ; chars in buffer so far
  1197.     mov    es:word ptr [0],cx    ; store count word
  1198.     xor    dx,dx            ; brace count
  1199.     or    cx,cx
  1200.     jg    gcmdl11            ; g = material at hand
  1201.     call    takclos            ; empty take file
  1202.     jmp    short gcmdl14        ; finish up
  1203.                     ; scan for command "stay"
  1204. gcmdl11:mov    ax,es:[si]        ; get 2 bytes, cx and si are set above
  1205.     inc    si            ; increment by only one char
  1206.     dec    cx
  1207.     call    bracechk        ; check for braces
  1208.     jc    gcmdl12            ; c = brace found
  1209.     cmp    al,' '            ; separator?
  1210.     jbe    gcmdl12            ; be = yes, keep looking
  1211.     cmp    al,','             ; comma separator?
  1212.     je    gcmdl12            ; e = yes
  1213.     or    dx,dx            ; within braces?
  1214.     jnz    gcmdl12            ; nz = yes, skip STAY search
  1215.     or    ax,2020h        ; convert to lower case
  1216.     cmp    ax,'ts'            ; first two letters of stay
  1217.     jne    gcmdl12            ; ne = no match
  1218.     mov    ax,es:[si+1]        ; next two letters (stay vs status)
  1219.     or    ax,2020h        ; convert to lower case
  1220.     cmp    ax,'ya'            ; same as our pattern?
  1221.     jne    gcmdl12            ; ne = no match
  1222.     add    si,3            ; char after "stay"
  1223.     sub    cx,3
  1224.                     ; check for separator or end of macro
  1225.     cmp    byte ptr es:[si],' '    ; next char is a separator?
  1226.     jbe    gcmdl13            ; be = yes, found correct match
  1227.     cmp    byte ptr es:[si],','    ; or comma separator?
  1228.     je    gcmdl13            ; e = yes
  1229.     or    cx,cx            ; at end of macro?
  1230.     jle    gcmdl13            ; yes, consider current match correct
  1231. gcmdl12:or    cx,cx            ; done yet? ("stay" not found)
  1232.     jg    gcmdl11            ; g = not yet, look some more
  1233.     mov    si,offset eexit        ; append command "exit"
  1234.     mov    cx,leexit        ; length of string "exit"
  1235.     add    [bx].takcnt,cx
  1236.     rep    movsb            ; copy it into the Take buffer
  1237. gcmdl13:mov    [bx].takptr,2        ; init buffer ptr
  1238.     mov    cx,[bx].takcnt        ; count of bytes in buffer
  1239.     mov    es:[0],cx        ; count of bytes in Take buffer
  1240. gcmdl14:pop    es
  1241.     ret
  1242. gcmdlin    endp
  1243.  
  1244. ; Curly brace checker. Examine (and preserve) char in AL. Count up/down
  1245. ; braces in dx because DS is unknown here
  1246. bracechk proc    near
  1247.     cmp    al,braceop        ; opening brace?
  1248.     jne    bracech1        ; ne = no
  1249.     inc    dx            ; count up braces
  1250.     stc                ; say brace seen
  1251.     ret
  1252. bracech1:cmp    al,bracecl        ; closing brace
  1253.     jne    bracech3        ; ne = no
  1254.     sub    dx,1            ; count down with sign
  1255.     jns    bracech2        ; ns = no underflow
  1256.     xor    dx,dx            ; don't go below zero
  1257. bracech2:stc                ; say brace detected
  1258.     ret
  1259. bracech3:clc                ; say brace not found
  1260.     ret
  1261. bracechk endp
  1262.  
  1263. ; Enter with ax pointing to file name.  Searches path for given file,
  1264. ; returns with ax pointing to whole name, or carry set if file can't be found.
  1265. SPATH    proc    near
  1266.     call    isfile            ; does it exist as it is?
  1267.     jc    spath0            ; c = no, prepend path elements
  1268.     test    byte ptr filtst.dta+21,10H ; subdirectory name?
  1269.     jnz    spath0            ; nz = yes, not desired file
  1270.     clc
  1271.     ret
  1272. spath0:    push    es            ; save es around work
  1273.     push    bx
  1274.     push    si
  1275.     push    di
  1276.     mov    bx,ax            ; save filename pointer in bx
  1277.     mov    si,ax
  1278.     xor    dl,dl            ; no '\' seen yet
  1279.     cld
  1280. spath1:    lodsb
  1281.     cmp    al,2fh            ; contains fwd slash path characters?
  1282.     je    spath1a
  1283.     cmp    al,5ch            ; or backslash?
  1284.     jne    spath2            ; no, keep going
  1285. spath1a:mov    dl,1            ; remember we've seen them
  1286. spath2:    or    al,al
  1287.     jnz    spath1            ; copy name in
  1288.     or    dl,dl            ; look at flag
  1289.     jz    spath3            ; no path, keep looking
  1290.     jmp    short spath9        ; embedded path, fail
  1291.  
  1292. spath3:    mov    si,pthadr        ; offset of PATH= string in environment
  1293.     mov    es,psp
  1294.     mov    di,es:word ptr[env]    ; pick up environment segment
  1295.     mov    es,di
  1296. spath4:    cmp    byte ptr es:[si],0    ; end of PATH= string?
  1297.     je    spath9            ; e = yes, exit loop
  1298.     mov    di,offset decbuf+64    ; place to put name
  1299. spath5:    mov    al,byte ptr es:[si]    ; get a byte from environment string
  1300.     inc    si
  1301.     cmp    al,';'            ; end of this part?
  1302.     je    spath7            ; yes, break loop
  1303.     or    al,al            ; maybe end of string?
  1304.     jnz    spath6            ; nz = no, keep going
  1305.     dec    si            ; back up to null for later rereading
  1306.     jmp    short spath7        ; and break loop
  1307. spath6:    mov    byte ptr [di],al    ; else stick in dest string
  1308.     inc    di
  1309.     jmp    short spath5        ; and continue
  1310. spath7:    push    si            ; save this ptr
  1311.     mov    si,bx            ; this is user's file name
  1312.     cmp    byte ptr [di-1],2fh    ; does path end with switch char?
  1313.     je    spath8            ; yes, don't put one in
  1314.     cmp    byte ptr [di-1],5ch    ; how about this one?
  1315.     je    spath8            ; yes, don't put it in
  1316.     mov    byte ptr [di],5ch    ; else add one
  1317.     inc    di
  1318. spath8:    lodsb                ; get filename character
  1319.     mov    byte ptr [di],al    ; copy filename char to output buffer
  1320.     inc    di
  1321.     or    al,al            ; end of string?
  1322.     jnz    spath8            ; nz = no, copy rest of name
  1323.     pop    si            ; restore postion in path string
  1324.     mov    ax,offset decbuf+64
  1325.     call    isfile            ; is it a file?
  1326.     jc    spath4            ; c = no, keep looking
  1327.     test    byte ptr filtst.dta+21,10H ; subdirectory name?
  1328.     jnz    spath4            ; nz = yes
  1329.     pop    di
  1330.     pop    si
  1331.     pop    bx
  1332.     pop    es
  1333.     clc
  1334.     ret                ; return success (carry clear)
  1335. spath9:    mov    ax,bx            ; restore original filename pointer
  1336.     pop    di            ; restore regs
  1337.     pop    si
  1338.     pop    bx
  1339.     pop    es
  1340.     stc                ; no file found
  1341.     ret
  1342. spath    endp
  1343.  
  1344. ; Put offset of PATH= string in pthadr
  1345. getpath    proc    near
  1346.     push    bx
  1347.     push    cx
  1348.     push    dx
  1349.     mov    bx,offset pthnam    ; thing    to find
  1350.     mov    cx,pthlen        ; length of it
  1351.     mov    pthadr,0        ; init offset to zero
  1352.     call    getenv            ; get environment value
  1353.     mov    pthadr,dx
  1354.     pop    dx
  1355.     pop    cx
  1356.     pop    bx
  1357.     ret
  1358. getpath    endp
  1359.  
  1360. ; getcsp: copy COMSPEC= environment string into cmspbuf
  1361. ; getssp: copy SHELL=   environment string into shellbuf
  1362. getcsp    proc    near
  1363.     mov    bx,offset cmspnam    ; find COMSPEC=
  1364.     mov    cx,cmsplen        ; it's length
  1365.     mov    di,offset cmspbuf    ; where to store string
  1366.     jmp    short getccom        ; do common worker
  1367.  
  1368. getssp:    mov    bx,offset shellnam    ; find SHELL=
  1369.     mov    cx,shellen        ; it's length
  1370.     mov    di,offset shellbuf    ; where to store string
  1371.     
  1372. getccom:push    es
  1373.     call    getenv            ; get environment offset into dx
  1374.     mov    si,dx            ; address of COMSPEC= string
  1375.     mov    es,psp
  1376.     mov    bx,es:word ptr[env]    ; pick up environment address
  1377.     mov    es,bx
  1378.     push    ds            ; save ds
  1379.     push    ds            ; make ds point to environment seg
  1380.     push    es            ; make es point to data segment
  1381.     pop    ds
  1382.     pop    es
  1383.     cld
  1384. getcs1:    lodsb                ; get a byte from environment
  1385.     cmp    al,' '            ; space or less?
  1386.     jg    getcs2            ; g = no, keep copying
  1387.     xor    al,al            ; terminate string on spaces etc
  1388. getcs2:    stosb                ; store it in destination
  1389.     or    al,al            ; at end of string yet?
  1390.     jnz    getcs1            ; nz = no, keep copying
  1391.     pop    ds            ; recover ds
  1392.     pop    es
  1393.     ret
  1394. getcsp    endp
  1395.  
  1396. ; Get Kermit parameters from the Environment. Parameters are commands like
  1397. ; regular commands except they do not appear in the SET main table and are
  1398. ; separated from one another by semicolons. They appear after KERMIT=.
  1399. ; Do not allow Take/Macros to be created by any of these commands.
  1400. ; On fatal error exits with carry set and flags.extflg = 1
  1401. getparm    proc    near
  1402.     push    ax
  1403.     push    bx
  1404.     push    cx
  1405.     push    dx
  1406.     push    si
  1407.     push    di
  1408.     push    es
  1409.     mov    es,psp            ; segment of our PSP
  1410.     mov    ax,es:word ptr[env]    ; pick up environment address
  1411.     mov    es,ax
  1412.     mov    bx,offset kerenv    ; Environment word to find, asciiz
  1413.     mov    dx,bx
  1414.     call    strlen            ; length of its string to cx
  1415.     call    getenv            ; return dx = offset in environment
  1416.     jnc    getpar1            ; nc = success
  1417.     jmp    getpar9            ; c = not found
  1418. getpar1:push    ds            ; save regular DS
  1419.     push    dx            ; push Environment offset, then seg
  1420.     push    es
  1421.     call    takopen            ; open Take buffer in macro space
  1422.     jnc    getpar2            ; nc = success
  1423.     mov    flags.extflg,1        ; say exit now
  1424.     pop    es            ; clean stack
  1425.     pop    dx
  1426.     pop    ds
  1427.     jmp    getparx            ; exit with fatal error
  1428.  
  1429. getpar2:mov    bx,takadr        ; bx = Take data structure
  1430.     mov    byte ptr [bx].taktyp,0ffh ; mark as a macro
  1431.     mov    [bx].takcnt,0        ; length of text
  1432.     mov    es,[bx].takbuf        ; ES = segment of buffer, from takopen
  1433.     mov    di,2            ; skip count word field for es:di
  1434.     pop    ds            ; pop Environment segment (was in ES)
  1435.     pop    si            ;  and seg, DS:SI is now Environment
  1436.     xor    cx,cx            ; line length counter
  1437. getpar3:lodsb                ; read an Environment character
  1438.     or    al,al            ; null (EOL)?
  1439.     jz    getpar5            ; z = yes, stop here
  1440.     cmp    al,';'            ; semicolon separator?
  1441.     jne    getpar4            ; ne = no
  1442.     mov    al,CR            ; replace semicolon with carriage ret
  1443. getpar4:stosb                ; store char in Take buffer
  1444.     inc    cx            ; count line length
  1445.     jmp    short getpar3        ; get more text, until a null
  1446.  
  1447. getpar5:mov    al,CR            ; terminate line, regardless
  1448.     stosb
  1449.     inc    cx            ; count terminator
  1450.     pop    ds            ; restore regular DS
  1451.     mov    [bx].takcnt,cx        ; chars in Take/macro buffer
  1452.     mov    es:[0],cx        ; store count byte
  1453.     mov    [bx].takptr,2        ; init buffer read ptr to first char
  1454.     jcxz    getpar8            ; z = nothing left, exit
  1455.                     ; parse each item as a command
  1456. getpar6:mov    comand.cmquiet,1    ; no screen display
  1457.     mov    dx,offset nulprmpt    ; set null prompt
  1458.     call    prompt
  1459.     cmp    flags.extflg,0        ; exit flag set?
  1460.     jne    getpar8            ; ne = yes, exit this routine now
  1461.     mov    dx,offset initab    ; table of initialization routines
  1462.     xor    bx,bx            ; no explict help text
  1463.     mov    comand.cmcr,1        ; allow bare CR's
  1464.     mov    comand.impdo,0        ; do not search Macro table
  1465.         mov    ah,cmkey        ; match a keyword
  1466.     call    comnd
  1467.     jc    getpar7            ; c = failure
  1468.     mov    comand.cmcr,0        ; no more bare CR's
  1469.     call    bx            ; call the routine returned in BX
  1470.                     ; ignore failures (carry bit set)
  1471. getpar7:cmp    taklev,0        ; finished Take file?
  1472.     je    getpar8            ; e = yes
  1473.     cmp    flags.extflg,0        ; exit flag set?
  1474.     je    getpar6            ; e = no, finish all commands
  1475.  
  1476. getpar8:call    takclos            ; close our take file, if open
  1477. getpar9:mov    flags.extflg,0        ; do not leave this flag set
  1478.     clc                ; clear for success
  1479. getparx:mov    comand.cmquiet,0    ; regular screen echoing
  1480.     pop    es
  1481.     pop    di
  1482.     pop    si
  1483.     pop    dx
  1484.     pop    cx
  1485.     pop    bx
  1486.     pop    ax
  1487.     ret
  1488. getparm    endp
  1489.  
  1490. ; Locate string variable in Environment
  1491. ; bx = variable to find (usually including =), cx = length of variable name.
  1492. ; Returns dx = offset within Environment of char following the name and
  1493. ; carry clear, else carry set and dx unchanged.
  1494. getenv    proc    near
  1495.     push    ax
  1496.     push    cx
  1497.     push    si
  1498.     push    di
  1499.     push    es
  1500.     mov    es,psp
  1501.     mov    ax,es:word ptr[env]    ; pick up environment address
  1502.     mov    es,ax
  1503.     xor    di,di            ; start at offset 0 in segment
  1504. geten1:    cmp    es:byte ptr [di],0    ; end of environment?
  1505.     je    geten3            ; yes, forget it
  1506.     push    cx            ; save counter
  1507.     push    di            ; and offset
  1508.     mov    si,bx
  1509.     cld
  1510.     repe    cmpsb            ; search for name
  1511.     pop    di
  1512.     pop    cx            ; restore these
  1513.     je    geten2            ; found it, break loop
  1514. getenv5:push    cx            ; preserve again
  1515.     mov    cx,0ffffh        ; bogus length
  1516.     xor    al,al            ; 0 = marker to look for
  1517.     repne    scasb            ; search for it
  1518.     pop    cx            ; restore length
  1519.     jmp    short geten1        ; loop thru rest of environment
  1520. geten2:    add    di,cx            ; skip to definition
  1521. geten6:    mov    si,bx            ; name
  1522.     add    si,cx            ; length
  1523.     cmp    byte ptr [si-1],'='    ; caller wanted '=' as last char?
  1524.     je    geten7            ; e = yes, and we found it
  1525.     mov    al,es:[di]        ; get next char
  1526.     cmp    al,'='            ; at the equals sign?
  1527.     je    geten7            ; e = yes
  1528.     inc    di            ; point at next char
  1529.     cmp    al,' '            ; white space?
  1530.     jbe    geten6            ; be = yes, skip over this
  1531.     dec    di            ; backup
  1532.     jmp    short getenv5        ; not a match, keep looking
  1533. geten7:    mov    dx,di            ; store offset of string
  1534.     clc                ; carry clear for success
  1535.     jmp    short geten4
  1536. geten3:    stc                ; carry set for failure
  1537. geten4:    pop    es
  1538.     pop    di
  1539.     pop    si
  1540.     pop    cx
  1541.     pop    ax
  1542.     ret
  1543. getenv    endp
  1544.  
  1545. ; Get thousands separator from DOS Country Information
  1546. gettsep    proc    near
  1547.     mov    ah,38h            ; Get Country Information
  1548.     mov    dx,offset tmpbuf    ; temp buffer
  1549.     int    dos
  1550.     mov    bx,7            ; assume DOS 3+ position in buffer
  1551.     cmp    byte ptr dosnum+1,3    ; DOS 3 or above?
  1552.     jae    gettse1            ; ae = yes
  1553.     mov    bx,4            ; for DOS 2.1
  1554.     cmp    dosnum,210h        ; earlier than version 2.1?
  1555.     jae    gettse1            ; ae = no
  1556.     mov    al,','            ; use comma for old DOS's
  1557. gettse1:mov    al,tmpbuf[bx]        ; get thousands separator char
  1558.     mov    thsep,al        ; save it
  1559.     mov    al,tmpbuf        ; get time/date format code
  1560.     mov    tdfmt,al        ; save it
  1561.     ret
  1562. gettsep    endp
  1563.  
  1564. STAY    PROC    NEAR
  1565.     clc
  1566.     ret
  1567. STAY    ENDP
  1568.  
  1569. CLS    proc    near            ; Clear command level screen
  1570.     mov    ah,cmeol        ; get a confirmation
  1571.     call    comnd
  1572.     jc    cls1            ; c = failure
  1573.     call    cmblnk            ; blank the screen
  1574.     call    locate            ; put cursor at home position
  1575. cls1:    ret
  1576. CLS    endp
  1577.  
  1578. COMNT    PROC    NEAR            ; COMMENT command
  1579.     mov    ah,cmline
  1580.     mov    bx,offset tmpbuf
  1581.     xor    dx,dx
  1582.     call    comnd
  1583.     jc    comnt1
  1584.     mov    ah,cmeol
  1585.     call    comnd
  1586. comnt1:    ret
  1587. COMNT    ENDP
  1588.  
  1589. ; change working directory
  1590. cwdir    proc    near
  1591.     mov    kstatus,kssuc        ; global status
  1592.     mov    ah,cmword
  1593.     mov    dx,offset tmpbuf
  1594.     mov    bx,offset pthmsg
  1595.     mov    word ptr tmpbuf,0
  1596.     call    comnd            ; get drive/dir spec, if any
  1597.     mov    ah,cmeol
  1598.     call    comnd
  1599.     jnc    cwd1
  1600.     ret                ; c = failure
  1601. cwd1:    mov    si,offset tmpbuf    ; cdsr wants drive/path ptr in si
  1602.     call    cdsr            ; common CD sub-routine
  1603.     jnc    cwd2            ; nc = success
  1604.     mov    kstatus,ksgen        ; global status for unsuccess
  1605. cwd2:    cmp    taklev,0        ; in a Take file or macro?
  1606.     je    cwd3            ; e = no, do echo
  1607.     cmp    flags.takflg,0        ; ok to echo?
  1608.     je    cwd4            ; e = no
  1609. cwd3:    push    dx
  1610.     mov    dx,offset crlf        ; msgs from cdsr don't include this
  1611.     mov    ah,prstr        ; so let's do it now
  1612.     int    dos
  1613.     pop    dx
  1614.     call    prtasz            ; output current drive/path or err msg
  1615. cwd4:    clc
  1616.     ret
  1617. cwdir    endp
  1618.  
  1619. ; CDSR processes both CD & REM CD.  Entered with si --> drive/path, it returns
  1620. ; dx --> ASCIIZ current drive/path, w/carry clear, if successful, or error msg
  1621. ; w/carry set, if not.
  1622. CDSR    PROC
  1623.     mov    kstatus,kssuc        ; global status
  1624.     xor    cx,cx            ; 0 for default drive, if none
  1625.     cmp    byte ptr[si],ch        ; any drive/path?
  1626.     je    cdsr4            ; e = no, just format current drive/path
  1627.     cmp    byte ptr[si+1],':'    ; is drive specified?
  1628.     jne    cdsr1            ; ne = no
  1629.     mov    cl,[si]            ; drive letter
  1630.     cmp    byte ptr[si+2],ch    ; any path?
  1631.     jne    cdsr1            ; ne = yes
  1632.     mov    word ptr[si+2],'.'    ; append dot+null as path to kludge DOS
  1633. cdsr1:    call    dskspace        ; test for drive, spec'd by cl, ready
  1634.     jnc    cdsr2            ; nc = ready
  1635.     mov    spcmsg3,cl        ; insert drive letter ret'd by dskspace
  1636.     mov    dx,offset spcmsg2+2    ; in err msg.  dx --> msg w/o cr,lf
  1637.     mov    kstatus,ksgen        ; global status
  1638.     ret                ; carry is set
  1639.  
  1640. cdsr2:    mov    dx,si            ; where chdir wants it
  1641.     mov    ah,chdir
  1642.     int    dos
  1643.     jnc    cdsr3            ; nc = success
  1644.     mov    dx,offset ermes4    ; ret carry set, dx --> err msg
  1645.     ret
  1646.  
  1647. cdsr3:    mov    dl,cl            ; uc drive letter ret'd by dskspace
  1648.     sub    dl,'A'            ; A = 0 for seldsk
  1649.     mov    ah,seldsk
  1650.     int    dos
  1651.     inc    dl            ; A = 1 for curdsk
  1652.     mov    curdsk,dl
  1653. cdsr4:    push    si            ; use caller's buffer for cur dr/path
  1654.     mov    ax,':@'            ; al = 'A' - 1, ah = ':'
  1655.     add    al,curdsk        ; al = drive letter
  1656.     mov    [si],ax            ; stash drive:
  1657.     inc    si
  1658.     inc    si
  1659.     mov    byte ptr[si],'\'    ; add \
  1660.     inc    si
  1661.     mov    ah,gcd            ; gcd fills in path as ASCIIZ
  1662.     xor    dl,dl            ; use current drive
  1663.     int    dos
  1664.     pop    dx            ; return caller's buffer pointer in dx
  1665.     clc
  1666.     ret
  1667. CDSR    ENDP
  1668.  
  1669. ; Erase specified file(s). Add protection of ignore hidden, subdir, volume
  1670. ; label and system files. 9 Jan 86 [jrd]
  1671. DELETE    PROC    NEAR            ; includes paths and "?*" wildcards
  1672.     mov    kstatus,kssuc        ; global status
  1673.     mov    si,offset delcmd    ; del command
  1674.     mov    di,offset tmpbuf
  1675.     call    strcpy
  1676.     mov    dx,offset tmpbuf
  1677.     call    strlen            ; get its length
  1678.     add    di,cx            ; point at terminator
  1679.     mov    temp,di            ; remember starting spot
  1680.     mov    ah,cmline        ; get a line
  1681.     mov    bx,di            ; where to place the file spec
  1682.     mov    dx,offset filmsg    ; help message
  1683.     call    comnd
  1684.     jc    delet0            ; c = failure
  1685.     push    ax
  1686.     mov    ah,cmeol
  1687.     call    comnd
  1688.     pop    ax
  1689.     jc    delet0
  1690.     or    ax,ax            ; anything given?
  1691.     jnz    delet1            ; nz = yes
  1692.     mov    ah,prstr
  1693.     mov    dx,offset ermes1    ; say need something
  1694.     int    dos
  1695.     clc                ; say success
  1696. delet0:    mov    kstatus,ksgen        ; global status
  1697.     ret
  1698.  
  1699. delet1:    mov    di,temp            ; start of filespec
  1700.     xor    cl,cl            ; disk drive letter
  1701.     cmp    byte ptr [di+1],':'    ; drive specified?
  1702.     jne    delet2            ; ne = no
  1703.     mov    cl,[di]            ; get drive letter
  1704. delet2:    call    dskspace        ; compute space, get letter into CL
  1705.     jnc    delet3            ; nc = success
  1706.     mov    spcmsg3,cl        ; put drive letter in msg
  1707.     mov    dx,offset spcmsg2    ; error message
  1708.     call    prtasz
  1709.     mov    kstatus,ksgen        ; global status
  1710.     clc
  1711.     ret                ; and ignore this command
  1712. delet3:    mov    si,offset tmpbuf    ; del cmd
  1713.     jmp    crun            ; join run cmd from there
  1714. DELETE    ENDP
  1715.  
  1716. ; Space <optional drive letter>
  1717.  
  1718. CHKDSK    PROC    NEAR            ; Space command
  1719.     mov    kstatus,kssuc        ; global status
  1720.     mov    dx,offset tmpbuf    ; buffer
  1721.     mov    tmpbuf,0        ; init to null
  1722.     mov    bx,offset dskmsg    ; help message
  1723.     mov    ah,cmword        ; get optional drive letter
  1724.     call    comnd            ; ignore errors
  1725.     mov    ah,cmeol
  1726.     call    comnd
  1727.     jnc    chkdsk1            ; nc = success
  1728.     ret                ; failure
  1729. chkdsk1:mov    cl,tmpbuf        ; set drive letter
  1730.     call    dskspace        ; compute space, get letter into CL
  1731.     jnc    chkdsk2            ; nc = success
  1732.     and    cl,5fh            ; to upper case
  1733.     mov    spcmsg3,cl        ; insert drive letter
  1734.     mov    dx,offset spcmsg2    ; say drive not ready
  1735.     call    prtasz
  1736.     mov    kstatus,ksgen        ; global status
  1737.     clc
  1738.     ret
  1739.     
  1740. chkdsk2:mov    spcmsg1,cl        ; insert drive letter
  1741.     mov    di,offset tmpbuf    ; work space for lnout
  1742.     mov    word ptr[di],0a0dh    ; cr/lf
  1743.     mov    word ptr[di+2],'  '    ; add two spaces
  1744.     add    di,4
  1745.     call    lnouts            ; use thousands separator
  1746.     mov    si,offset spcmsg
  1747.     call    strcat            ; add text to end of message
  1748.     mov    dx,offset tmpbuf
  1749.     call    prtasz            ; print asciiz string
  1750.     clc
  1751.     ret
  1752. CHKDSK    ENDP
  1753.  
  1754. ; Compute disk free space (bytes) into long word dx:ax.
  1755. ; Enter with disk LETTER in CL (use null if current disk).
  1756. ; Returns uppercase drive letter in CL.
  1757. ; Returns carry set if drive access error. Changes AX, DX.
  1758.  
  1759. DSKSPACE PROC    NEAR
  1760.     mov    dl,cl            ; desired disk letter, or null
  1761.     or    dl,dl            ; use current disk?
  1762.     jnz    dskspa1            ; nz = no
  1763.     mov    ah,gcurdsk        ; get current disk
  1764.     int    dos
  1765.     add    al,'A'            ; make 0 ==> A
  1766.     mov    dl,al
  1767. dskspa1:and    dl,5fh            ; convert to upper case
  1768.     mov    cl,dl            ; return upper case drive letter in CL
  1769.     sub    dl,'A'-1        ; 'A' is 1, etc
  1770.     push    bx
  1771.     push    cx
  1772.     mov    ah,36h            ; get disk free space, bx=sect/cluster
  1773.     int    dos            ; dx:ax=sectors, cx=bytes/sector
  1774.     cmp    ax,0ffffh        ; error response?
  1775.     jne    dskspa2            ; ne = no
  1776.     pop    cx
  1777.     pop    bx
  1778.     stc                ; return error
  1779.     ret
  1780. dskspa2:mul    bx            ; sectors/cluster * clusters = sectors
  1781.     mov    bx,dx            ; save high word of sectors (> 64K)
  1782.     mul    cx            ; bytes = sectors * bytes/sector
  1783.     push    ax            ; save low word of bytes
  1784.     mov    ax,bx            ; recall sectors high word
  1785.     mov    bx,dx            ; save current bytes high word
  1786.     mul    cx            ; high word sectors * bytes/sector
  1787.     add    ax,bx            ; new high bytes + old high bytes
  1788.     mov    dx,ax            ; store high word in dx
  1789.     pop    ax            ; space is in dx:ax as a long word
  1790.     pop    cx
  1791.     pop    bx
  1792.     clc
  1793.     ret
  1794. DSKSPACE ENDP
  1795.  
  1796. ; Get directory    listing
  1797. DIRECT    PROC    NEAR
  1798.     mov    kstatus,kssuc        ; global status
  1799.     mov    si,offset dircmd    ; dir command
  1800.     mov    di,offset tmpbuf
  1801.     call    strcpy
  1802.     mov    dx,offset tmpbuf
  1803.     call    strlen            ; get its length
  1804.     add    di,cx            ; point at terminator
  1805.     mov    temp,cx            ; remember length
  1806.     mov    ah,cmline        ; parse with cmline to allow switches
  1807.     mov    bx,di            ; next available byte
  1808.     mov    dx,offset filmsg    ; help message 
  1809.     call    comnd
  1810.     jnc    direct1            ; nc = success
  1811. direct0:mov    kstatus,ksgen        ; global status
  1812.     ret                ; failure
  1813. direct1:mov    ah,cmeol
  1814.     call    comnd
  1815.     jc    direct0
  1816.     mov    word ptr [bx],0        ; plant terminator
  1817.     mov    cl,curdsk        ; current drive number ('A'=1)
  1818.     add    cl,'A'-1        ; make a letter
  1819.     mov    si,offset tmpbuf
  1820.     push    si
  1821.     add    si,temp            ; user's text after ' dir '
  1822.     cmp    byte ptr [si+1],':'    ; drive specified?
  1823.     jne    direct2            ; ne = no, use current drive
  1824.     mov    cl,[si]            ; get drive letter from buffer
  1825. direct2:call    dskspace        ; check for drive ready
  1826.     pop    si
  1827.     jnc    direct3            ; nc = drive ready
  1828.     mov    spcmsg3,cl        ; insert letter
  1829.     mov    dx,offset spcmsg2    ; say drive is not ready
  1830.     call    prtasz
  1831.     mov    kstatus,ksgen        ; global status
  1832.     stc
  1833.     ret
  1834. direct3:jmp    crun            ; join run cmd from there
  1835. DIRECT    ENDP
  1836.  
  1837. ; This is the 'HELP' command.  It gives a list of the commands
  1838.  
  1839. HELP    PROC    NEAR
  1840.     mov    kstatus,kssuc        ; global status
  1841.     mov    ah,cmeol
  1842.     call    comnd            ; get a confirm
  1843.     jnc    help1            ; nc = success
  1844.     ret                ; failure
  1845.  
  1846. help1:    push    ds            ; changing data segments!
  1847.     push    es
  1848.     mov    ax,ds
  1849.     mov    es,ax            ; for escchr
  1850.     mov    ax,data1        ; new data segment
  1851.     mov    ds,ax
  1852.     ; warning
  1853.     assume    ds:data1
  1854.     mov    ah,prstr        ; show Quick help summary screen
  1855.     mov    dx,offset qckhlp
  1856.     int    dos
  1857.     mov    ah,conout
  1858.     mov    dl,es:trans.escchr    ; get Kermit escape character
  1859.     add    dl,40h            ; convert to printable
  1860.     push    dx            ; save it for repeats below
  1861.     int    dos
  1862.     mov    ah,prstr
  1863.     mov    dx,offset qckhlp1    ; more help text
  1864.     int    dos
  1865.     mov    ah,conout
  1866.     pop    dx
  1867.     push    dx
  1868.     int    dos
  1869.     mov    ah,prstr
  1870.     mov    dx,offset qckhlp2    ; more help text
  1871.     int    dos
  1872.     pop    dx            ; recover current escape char
  1873.     mov    ah,conout
  1874.     int    dos
  1875.     mov    ah,prstr
  1876.     mov    dx,offset qckhlp3    ; end of help message
  1877.     int    dos
  1878.     mov    ah,coninq        ; get a keystroke, quietly
  1879.     int    dos
  1880.     cmp    es:flags.cxzflg,'C'    ; Control-C?
  1881.     je    helpend            ; e = yes, quit now
  1882.     cmp    al,3
  1883.     je    helpend
  1884.     cmp    al,' '            ; space bar?
  1885.     je    help2            ; ne = no, skip second screen
  1886.     jmp    short helpend        ; switch data segments
  1887.  
  1888. help2:    mov    ah,prstr        ; show second Quick help summary
  1889.     mov    dx,offset qckhlp5
  1890.     int    dos
  1891.     mov    ah,coninq
  1892.     int    dos
  1893.     cmp    es:flags.cxzflg,'C'    ; Control-C?
  1894.     je    helpend            ; e = yes, quit now
  1895.     cmp    al,3
  1896.     je    helpend
  1897.     cmp    al,'?'            ; query mark?
  1898.     je    helpquery        ; e = yes do main query help
  1899.     mov    ah,prstr
  1900.     mov    dx,offset qckhlp6
  1901.     int    dos
  1902.     mov    ah,coninq
  1903.     int    dos
  1904.     cmp    es:flags.cxzflg,'C'    ; Control-C?
  1905.     je    helpend            ; e = yes, quit now
  1906.     cmp    al,3
  1907.     je    helpend
  1908.     cmp    al,'?'            ; query mark?
  1909.     je    helpquery        ; e = yes do main query help
  1910.     mov    ah,prstr
  1911.     mov    dx,offset qckhlp7
  1912.     int    dos
  1913. helpend:pop    es
  1914.     pop    ds            ; restore regular data seg data
  1915.     ; warning
  1916.     assume    ds:data
  1917.     clc
  1918.     ret
  1919. helpquery:
  1920.     pop    es
  1921.     pop    ds            ; restore regular data seg data
  1922.     ; warning
  1923.     assume    ds:data
  1924.     mov    ah,prstr        ; show help summary screen
  1925.     mov    dx,offset crlf        ; a few blank lines
  1926.     int    dos
  1927.     int    dos
  1928.     int    dos
  1929.     mov    dx,offset tophlp    ; show usual cryptic help
  1930.     int    dos
  1931. helpx:    clc
  1932.     ret
  1933. HELP    ENDP
  1934.  
  1935. ; the version command - print our version number
  1936. prvers    proc    near
  1937.     mov    kstatus,kssuc        ; global status
  1938.     mov    ah,cmeol
  1939.     call    comnd
  1940.     jc    prvers1            ; c = failure
  1941.     mov    ah,prstr
  1942.     mov    dx,offset crlf
  1943.     int    dos
  1944.     mov    ah,prstr
  1945.     mov    dx,offset machnam    ; display machine name
  1946.     int    dos
  1947.     mov    ah,prstr        ; display the version header
  1948.     mov    dx,offset verident
  1949.     int    dos
  1950.     clc
  1951. prvers1:ret
  1952. prvers    endp
  1953.  
  1954. ; SHOW command dispatcher
  1955. showcmd    proc    near
  1956.     mov    ah,cmkey
  1957.     mov    dx,offset shotab
  1958.     xor    bx,bx            ; no canned help
  1959.     call    comnd
  1960.     jc    showc1            ; c = failure
  1961.     jmp    bx            ; execute the handler
  1962. showc1:    ret                ; failure
  1963. showcmd    endp
  1964.  
  1965. ; the type command - type out a file
  1966. typec    proc    near
  1967.     mov    kstatus,kssuc        ; global status
  1968.     mov    si,offset typcmd    ; type command
  1969.     mov    di,offset tmpbuf
  1970.     call    strcpy
  1971.     mov    dx,offset tmpbuf
  1972.     call    strlen            ; get its length
  1973.     add    di,cx            ; point at terminator
  1974.     mov    temp,di            ; save place for later
  1975.     mov    ah,cmline        ; parse with cmline, allows | more
  1976.     mov    bx,di            ; next available byte
  1977.     mov    dx,offset filmsg    ; In case user wants help
  1978.     call    comnd
  1979.     jc    typec1            ; c = failure
  1980.     push    ax
  1981.     mov    ah,cmeol
  1982.     call    comnd
  1983.     pop    ax
  1984.     jc    typec1
  1985.     or    ax,ax            ; any text given?
  1986.     jnz    typec2            ; nz = yes
  1987.     mov    ah,prstr
  1988.     mov    dx,offset ermes1    ; say need more info
  1989.     int    dos
  1990.     mov    kstatus,ksgen        ; global status
  1991.     clc
  1992. typec1:    ret
  1993. typec2:    mov    byte ptr [bx],0        ; plant terminator
  1994.     mov    si,temp            ; start of filespec
  1995.     xor    cl,cl            ; say local drive
  1996.     cmp    byte ptr [si+1],':'    ; drive given?
  1997.     jne    typec3            ; ne = no
  1998.     mov    cl,[si]            ; get drive letter
  1999. typec3:    call    dskspace        ; check for drive ready
  2000.     jnc    typec4
  2001.     mov    spcmsg3,cl        ; put drive letter in msg
  2002.     mov    dx,offset spcmsg2    ; error message
  2003.     call    prtasz
  2004.     mov    kstatus,ksgen        ; global status
  2005.     clc
  2006.     ret                ; and ignore this command
  2007. typec4:    mov    si,offset tmpbuf
  2008.     jmp    short crun        ; join run cmd from there
  2009. typec    endp
  2010.  
  2011. ; PUSH to DOS (run another copy of Command.com or equiv)
  2012. ; entry fpush (fast push...) pushes without waiting for a confirm
  2013. dopush    proc    near
  2014.     mov    ah,cmeol
  2015.     call    comnd
  2016.     jnc    fpush            ; nc = success
  2017.     ret                ; failure
  2018. fpush:    mov    si,offset tmpbuf    ; a dummy buffer
  2019.     mov    byte ptr [si],0        ; plant terminator
  2020.     mov    dx,offset cmspbuf    ; always use command.com
  2021.     cmp    shellbuf,0        ; SHELL= present?
  2022.     je    crun4            ; e = no, use COMSPEC= name
  2023.     mov    dx,offset shellbuf    ; use SHELL= name
  2024.     jmp    short crun4        ; go run it
  2025. dopush    endp
  2026.  
  2027. ; Run a program from within Kermit
  2028. RUN    PROC    NEAR
  2029.     mov    ah,cmline        ; get program name and any arguments
  2030.     mov    bx,offset tmpbuf    ; place for user's text
  2031.     mov    dx,offset runmsg    ; In case user wants help
  2032.     call    comnd
  2033.     jnc    run1            ; nc = success
  2034.     ret                ; failure
  2035. run1:    or    ax,ax            ; byte count
  2036.     jnz    run2            ; nz = have program name
  2037.     mov    ah,prstr        ; else complain
  2038.     mov    dx,offset ermes1    ; need more info
  2039.     int    dos
  2040.     clc
  2041.     ret
  2042. run2:    mov    si,offset tmpbuf    ; source of text
  2043.     jmp    short crun
  2044. RUN    ENDP
  2045.  
  2046. ; crun - run an arbitrary program.    Rewritten by [jrd]
  2047. ; Enter with ordinary asciiz command in si (such as Dir *.asm)
  2048. ; Append a c/r and a null terminator and then ask command.com to do it
  2049. ; Set errlev with DOS errorlevel from subprocess.
  2050. CRUN    proc    near
  2051.     mov    ah,prstr        ; output crlf before executing comnd
  2052.     mov    dx,offset crlf        ; [lba]
  2053.     int    dos
  2054.     mov    di,offset tmpbuf    ; where to put full command line text
  2055.     cmp    si,di            ; same place?
  2056.     je    crun1            ; e = yes, don't copy ourself
  2057.     call    strcpy            ; si holds source text
  2058. crun1:    mov    si,offset slashc    ; DOS command begins with slashc area
  2059.     mov    dx,offset slashc+1    ; si points to /c part of command line
  2060.     call    strlen            ; get its length into cx
  2061.     push    bx
  2062.     mov    bx,dx
  2063.     add    bx,cx
  2064.     mov    byte ptr [bx],cr    ; end string with a c/r for dos
  2065.     inc    cx            ; count the c/r
  2066.     mov    byte ptr [bx+1],0    ; and terminate
  2067.     pop    bx
  2068.     mov    [si],cl            ; put length of argument here
  2069.     mov    dx,offset cmspbuf    ; always use command.com
  2070. crun4:    mov    exearg+2,si        ; pointer to argument string
  2071.     mov    exearg+4,ds        ; segment of same
  2072.     cmp    lclsusp,0        ; sys dependent routine to call
  2073.     je    crun5            ; e = none
  2074.     mov    bx,lclsusp        ; address to call
  2075.     push    dx            ; preserve name in dx
  2076.     call    bx            ; call sys dependent suspend routine
  2077.     pop    dx
  2078. crun5:    push    dx            ; preserve name in dx
  2079.     call    serrst            ; reset serial port (if active)
  2080.     call    cbrestore        ; restore state of Control-Break Chk
  2081.     pop    dx
  2082.     mov    es,psp            ; point to psp again
  2083.     mov    exearg+8,es        ; segment of psp, use our def fcb's
  2084.     mov    exearg+12,es        ; segment of psp, ditto, for fcb 2
  2085.     mov    ax,es:word ptr [env]    ; get environment ptr
  2086.     mov    exearg,ax        ; put into argument block
  2087.     mov    ax,ds
  2088.     mov    es,ax            ; put es segment back
  2089.     mov    bx,offset exearg    ; es:bx points to exec parameter block
  2090.     mov    ax,ss            ; save ss:sp
  2091.     mov    word ptr ssave+2,ax
  2092.     mov    word ptr ssave,sp
  2093.     xor    al,al            ; 0 = load and execute (DX has name)
  2094.     mov    ah,exec
  2095.     int    dos            ; go run the program
  2096.     mov    ax,data            ; restore segment registers
  2097.     mov    ds,ax            ; reset data segment
  2098.     mov    es,ax            ; and extra segment
  2099.     cli
  2100.     mov    ax,word ptr ssave+2
  2101.     mov    ss,ax            ; and stack segment
  2102.     mov    sp,word ptr ssave    ; restore stack ptr
  2103.     sti
  2104.     jc    crun8            ; c = error, handle
  2105.     mov    ah,4dh            ; get subprocess return status
  2106.     int    dos
  2107.     mov    errlev,al        ; DOS errorlevel
  2108.     jmp    short crun9
  2109. crun8:    mov    ah,prstr        ; failure, complain
  2110.     mov    dx,offset erms37
  2111.     int    dos
  2112.     mov    kstatus,ksgen        ; global status
  2113. crun9:    mov    ah,setdma        ; restore dma buffer pointer
  2114.     mov    dx,offset buff
  2115.     int    dos            ; restore dma address!!
  2116.     call    cboff            ; turn off DOS BREAK check
  2117.     cmp    lclrest,0        ; sys dependent routine to call?
  2118.     je    crun10            ; e = none
  2119.     mov    bx,lclrest        ; get routine's address
  2120.     call    bx            ; call sys dependent restore routine
  2121. crun10:    clc
  2122.     ret
  2123. CRUN    ENDP
  2124. code    ends
  2125.  
  2126. code1    segment
  2127.     assume    cs:code1 
  2128. ; Replace Int 23h and Int 24h with our own handlers
  2129. ; Revised to ask DOS for original interrupt vector contents, as suggested by
  2130. ; Jack Bryans. 9 Jan 1986 jrd
  2131. ; Modified again 30 August 1986 [jrd]
  2132. SETINT    PROC    FAR
  2133.     push    es            ; save registers
  2134.     mov    al,23H            ; desired interrupt vector (^C)
  2135.     mov    ah,35H            ; Int 21H, function 35H = Get Vector
  2136.     int    dos            ; get vector in es:bx
  2137.     mov    in3ad,bx        ; save offset of original vector
  2138.     mov    in3ad+2,es        ;   and its segment
  2139.     mov    al,24h            ; DOS critical error, Int 24h
  2140.     mov    ah,35h
  2141.     int    dos
  2142.     mov    word ptr ceadr,bx    ; DOS's Critical Error handler, offset
  2143.     mov    word ptr ceadr+2,es    ;  and segment address
  2144.     push    ds            ; save ds around next DOS calls
  2145.     mov    ax,seg intbrk        ; compose full address of ^C routine
  2146.     mov    ds,ax            ; segment is the code segment
  2147.     mov    dx,offset intbrk    ;   and offset is intbrk
  2148.     mov    al,23H            ; on ^C, goto intbrk
  2149.     mov    ah,25H            ; set interrupt address from ds:dx
  2150.     int    dos
  2151.     mov    dx,offset dosce        ; replacement Critical Error handler
  2152.     mov    al,24h            ; interrupt 24h
  2153.     mov    ah,25h            ; replace it
  2154.     int    dos
  2155.     pop    ds
  2156.     mov    ax,3300h        ; get state of Control-Break Check
  2157.     int    dos
  2158.     mov    orgcbrk,dl        ; save state here
  2159.     pop    es
  2160.     ret
  2161. SETINT    ENDP
  2162.  
  2163. ; Control Break, Interrupt 23h replacement
  2164. ; Always return with a Continue (vs Abort) condition since Kermit will cope
  2165. ; with failures. [jrd]
  2166. intbrk:    push ax
  2167.     push    ds    
  2168.     mov    ax,data            ; get Kermit's data segment
  2169.     mov    ds,ax
  2170.     mov    flags.cxzflg,'C'    ; say we saw a ^C
  2171.     mov    rstate,'E'
  2172.     mov    sstate,'E'
  2173.     pop    ds
  2174.     pop    ax
  2175.     iret               ; return to caller in a Continue condition
  2176.  
  2177. ; Kermit's DOS Critical Error Handler, Int 24h. [jrd]
  2178. ; Needed to avoid aborting Kermit with the serial port interrupt active and
  2179. ; the Control Break interrupt redirected. See the DOS Tech Ref Manual for
  2180. ; a start on this material; it is neither complete nor entirely accurate
  2181. ; The stack is the Kermit's stack, the data segment is unknown, interrupts
  2182. ; are off, and the code segment is Kermit's. Note: some implementations of
  2183. ; MS DOS may leave us in DOS's stack. Called by a DOS Int 21h function
  2184. dosce:    test    ah,80h        ; block device (disk drive)?
  2185.     jnz    dosce1        ; nz = no; serial device, memory, etc
  2186.     mov    al,3        ; tell DOS to Fail the Int 21h call
  2187.     iret            ; return to DOS
  2188. dosce1:    add    sp,6        ; pop IP, CS, Flags regs, from DOS's Int 24h
  2189.     pop    ax        ; restore original callers regs existing
  2190.     pop    bx        ;  just before doing Int 21h call
  2191.     pop    cx
  2192.     pop    dx
  2193.     pop    si
  2194.     pop    di
  2195.     pop    bp
  2196.     pop    ds
  2197.     pop    es        
  2198.     mov    al,0ffh        ; signal failure (usually) the DOS 1.x way
  2199.     push    bp        ; Kermit's IP, CS, and Flags are on the stack
  2200.     mov    bp,sp        ;  all ready for an iret, but first a word ..
  2201.     or    word ptr[bp+8],1 ; set carry bit, signals failure DOS 2+ way
  2202.     pop    bp        ; this avoids seeing the Interrupt flag bit
  2203.     iret            ; return to user, simulate return from Int 21h
  2204. code1    ends
  2205.  
  2206. code    segment
  2207.     assume    cs:code
  2208.  
  2209. ; Set DOS' Control-Break Check to off
  2210. cboff    proc    near
  2211.     mov    ax,3301h        ; set Control-Break Chk state
  2212.     xor    dl,dl            ; set state to off
  2213.     int    dos
  2214.     ret
  2215. cboff    endp
  2216.  
  2217. ; Restore DOS's Control-Break Check to startup value
  2218. cbrestore proc    near
  2219.     push    dx
  2220.     mov    ax,3301h        ; set Control-Break Chk state
  2221.     mov    dl,orgcbrk        ; restore state to startup value
  2222.     int    dos
  2223.     pop    dx
  2224.     ret
  2225. cbrestore endp
  2226.  
  2227. ISFILE    PROC    NEAR
  2228. ; Enter with ds:ax pointing at asciiz filename string
  2229. ; Returns carry set if the file pointed to by ax does not exist, else reset
  2230. ; Returns status byte, fstat, with DOS status and high bit set if major error
  2231. ; Does a search-for-first to permit paths and wild cards
  2232. ; Examines All kinds of files (ordinary, subdirs, vol labels, system,
  2233. ;  and hidden). Upgraded to All kinds on 27 Dec 1985. Revised 30 Aug 86 [jrd]
  2234. ; All registers are preserved
  2235.     push    bx
  2236.     push    ax
  2237.     mov    bx,ax
  2238.     mov    ax,[bx]
  2239.     and    ax,not 2020h        ; to upper
  2240.     cmp    ax,'UN'            ; look for DOS 5 NUL
  2241.     jne    isfil4            ; ne = mismatch
  2242.     mov    ax,[bx+2]
  2243.     and    al,not 20h
  2244.     cmp    ax,'L'+0
  2245.     jne    isfil4            ; ne = mismatch
  2246.     pop    ax
  2247.     pop    bx
  2248.     clc                ; say success
  2249.     ret
  2250. isfil4:    pop    ax
  2251.     pop    bx
  2252.     push    dx            ; save regs
  2253.     push    cx
  2254.     push    ax
  2255.     mov    byte ptr filtst.dta+21,0 ; clear old attribute bits
  2256.     mov    byte ptr filtst.fname,0    ; clear any old filenames
  2257.     mov    filtst.fstat,0        ; clear status byte
  2258.     mov     cx,3fH            ; look at all kinds of files
  2259.     mov    dx,offset filtst.dta    ; own own temporary dta
  2260.     mov    ah,setdma        ; set to new dta
  2261.     int    dos
  2262.     pop    dx            ; get ax (filename string ptr)
  2263.     push    dx            ; save it again
  2264.     mov    ah,first2        ; search for first
  2265.     int    dos
  2266.     pushf                ; save flags
  2267.     mov    dx,offset buff        ; reset dma
  2268.     mov    ah,setdma
  2269.     int    dos
  2270.     popf                ; recover flags
  2271.     jnc    isfil1            ; nc = file found
  2272.     mov    filtst.fstat,al        ; record DOS status
  2273.     cmp    al,2            ; just "File Not Found"?
  2274.     je    isfil2            ; e = yes
  2275.     cmp    al,3            ; "Path not found"?
  2276.     je    isfil2            ; e = yes
  2277.     cmp    al,18            ; "No more files"?
  2278.     je    isfil2            ; e = yes
  2279.     or    filtst.fstat,80h    ; set high bit for more serious error
  2280.     jmp    short isfil2    
  2281. isfil1:    cmp    byte ptr filtst.fname,0    ; did DOS fill in a name?
  2282.     je    isfil2            ; z = no
  2283.     clc
  2284.     jmp    short isfil3
  2285. isfil2:    stc                ; else set carry flag bit
  2286. isfil3:    pop    ax
  2287.     pop    cx
  2288.     pop    dx
  2289.     ret                ; DOS sets carry if file not found
  2290. ISFILE    ENDP
  2291.  
  2292. ; initialize memory usage by returning to DOS anything past the end of kermit
  2293. memini    proc    near
  2294.     push    es
  2295.     mov    bx,_TEXT
  2296.     sub    bx,psp
  2297.     mov    totpar,bx        ; save for patcher's magic number
  2298.     mov    es,psp            ; address psp segment again
  2299.     mov    bx,offset msfinal + 15    ; end of pgm + roundup
  2300.     mov    cl,4
  2301.     shr    bx,cl            ; compute # of paragraphs in last seg
  2302.     mov    ax,_STACK        ; last segment
  2303.     sub    ax,psp            ; minus beginning
  2304.     add    bx,ax            ; # of paragraphs occupied
  2305.     mov    ah,setblk
  2306.     int    dos
  2307.     pop    es
  2308.     jnc    memin1
  2309.     mov    dx,offset ermes2
  2310.     mov    ah,prstr
  2311.     int    dos            ; complain
  2312.     jmp    krmend            ; exit Kermit now
  2313. memin1:    pop    dx            ; save return address here
  2314.     mov    ax,_STACK        ; move SS down to DGROUP, adj SP
  2315.     sub    ax,DGROUP        ; paragraphs to move
  2316.     mov    cl,4            ; convert to bytes
  2317.     shl    ax,cl
  2318.     mov    bx,SP            ; current SP offset
  2319.     add    bx,ax            ; new SP, same memory cell
  2320.     mov    ax,bx
  2321.     sub    ax,400            ; top 400 bytes = Kermit
  2322.     mov    tcptos,ax        ; report this as TCP's top of stack
  2323.     mov    ax,DGROUP        ; new SS
  2324.     cli
  2325.     mov    SS,ax
  2326.     mov    SP,bx            ; whew!
  2327.     sti
  2328.     push    dx            ; push return address
  2329.     clc
  2330.     ret
  2331. memini    endp
  2332.  
  2333. ; Allocate memory.  Passed a memory size in ax, allocates that many
  2334. ; bytes (actually rounds up to a paragraph) and returns its SEGMENT in ax
  2335. ; The memory is NOT initialized.  Written by [jrd] to allow memory to
  2336. ; be allocated anywhere in the 1MB address space
  2337. sbrk    proc    near            ; K & R, please forgive us
  2338.     mov    bx,ax            ; bytes wanted
  2339.     add    bx,15            ; round up
  2340.     mov    cl,4
  2341.     shr    bx,cl            ; convert to # of paragraphs
  2342.     mov    cx,bx            ; remember quantity wanted
  2343.     mov    ah,alloc        ; DOS memory allocator
  2344.     int    dos
  2345.     jc    sbrkx            ; c = fatal
  2346.     cmp    cx,bx            ; paragraphs wanted vs delivered
  2347.     jb    sbrkx            ; b = not enough, fatal error
  2348.     ret                ; and return segment in ax
  2349. sbrkx:    mov    dx,offset mfmsg        ; assume not enough memory (ax = 8)
  2350.     cmp    ax,7            ; corrupted memory (ax = 7)?
  2351.     jne    sbrkx1            ; ne = no
  2352.     mov    dx,offset mf7msg    ; corrupted memory found
  2353. sbrkx1:    mov    ah,prstr
  2354.     int    dos
  2355.     jmp    krmend            ; exit Kermit now
  2356. sbrk    endp
  2357. code     ends
  2358.     end    start
  2359.